# maintainer: Neophytos Kolokotronis <tetris4@gmail.com

_pkgbase='pidgin'
pkgname='libpurple'
pkgver=2.10.10
pkgrel=2
pkgdesc="IM library extracted from Pidgin"
arch=('x86_64')
url="http://pidgin.im/"
license=('GPL')
makedepends=('startup-notification' 'libxss' 'nss' 'libsasl' 'python2' 'silc-toolkit'
             'avahi' 'tk' 'ca-certificates' 'intltool' 'networkmanager')
depends=('libsasl' 'dbus-glib' 'silc-toolkit' 'nss>=3.17.1' 'nspr>=4.10.7' 'cyrus-sasl-plugins')
optdepends=('dbus-python: for purple-remote and purple-url-handler')
options=('!libtool')
source=(http://downloads.sourceforge.net/${_pkgbase}/${_pkgbase}-${pkgver}.tar.bz2)
md5sums=('5030d4750c73b211c7e82bb67ea3d016')

build() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    sed -i "s#env python#env python2#" */plugins/*.py
    sed -i "s#env python#env python2#" libpurple/purple-{remote,notifications-example,url-handler}
    ./configure --prefix=/usr \
                --sysconfdir=/etc \
                --disable-schemas-install \
                --disable-meanwhile \
                --disable-gtkui \
                --disable-screensaver \
                --disable-sm \
                --disable-gstreamer \
                --disable-vv \
                --disable-gtkspell \
                --enable-cyrus-sasl \
                --disable-doxygen \
                --with-python=/usr/bin/python2 \
                --with-system-ssl-certs=/etc/ssl/certs
    make
}

package() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    for dir in libpurple share/sounds share/ca-certs m4macros po
    do  make -C "${dir}" DESTDIR="${pkgdir}" install
    done
}