#
# Chakra Packages, part of chakra-project.org
#
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=junit
pkgver=4.11
pkgrel=1
pkgdesc="Automated testing framework for Java"
arch=('any')
url="http://www.junit.org/"
license=('CPL')
depends=('java-runtime')
makedepends=('apache-ant')
source=(https://github.com/junit-team/junit/archive/r${pkgver}.tar.gz)
md5sums=('bf62095e510f50baf0962af329438647')

build() {
  cd ${srcdir}/${pkgname}-r${pkgver}

  ant dist
}

check() {
  cd ${srcdir}/${pkgname}-r${pkgver}

  ant test
}

package() {
  cd ${srcdir}/${pkgname}-r${pkgver}/${pkgname}${pkgver}-SNAPSHOT

  install -dm755 ${pkgdir}/usr/share/java/${pkgname}
  install -m644 \
    ${pkgname}-${pkgver}-SNAPSHOT.jar \
    ${pkgname}-dep-${pkgver}-SNAPSHOT.jar \
    ${pkgdir}/usr/share/java/${pkgname}
  ln -s ${pkgname}-${pkgver}-SNAPSHOT.jar ${pkgdir}/usr/share/java/${pkgname}.jar
  ln -s ${pkgname}-dep-${pkgver}-SNAPSHOT.jar ${pkgdir}/usr/share/java/${pkgname}-dep.jar
}