#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=xz
pkgver=4.999.9beta
_snapshot=143-g3e49
pkgrel=4
pkgdesc='Library and command line tools for XZ and LZMA compressed files'
arch=('i686' 'x86_64')
url='http://tukaani.org/xz/'
license=('GPL' 'LGPL' 'custom')
depends=('sh')
provides=('lzma' 'lzma-utils' 'xz-utils')
replaces=('lzma' 'lzma-utils' 'xz-utils')
conflicts=('lzma' 'lzma-utils' 'xz-utils')
options=('!libtool')
source=("http://tukaani.org/${pkgname}/${pkgname}-${pkgver}-${_snapshot}.tar.gz")
md5sums=('9e5a42d2b5277d8d71405d065120bd4e')
build() {
        cd ${srcdir}/${pkgname}-$pkgver-${_snapshot}
        ./configure --prefix=/usr \
                --enable-dynamic \
                --disable-rpath \
                --enable-werror
        sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
        sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
        make
}
package() {
        cd ${srcdir}/${pkgname}-$pkgver-${_snapshot}
        make DESTDIR=${pkgdir} install
        install -d -m755 ${pkgdir}/usr/share/licenses/xz/
        ln -sf /usr/share/doc/xz/COPYING ${pkgdir}/usr/share/licenses/xz/
        ln -sf /usr/share/licenses/common/GPL2/license.txt ${pkgdir}/usr/share/doc/xz/COPYING.GPLv2
}