#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer: abveritas@chakra-project.org
# contributor Mladen Pejaković <pejakm@gmail.com>

pkgname=hunspell-sr
pkgver=20130117
pkgrel=1
pkgdesc="Serbian Cyrillic and Latin hunspell dictionaries"
arch=('x86_64')
url="http://gitorious.org/dict-sr/hunspell-sr"
license=('GPL' 'LGPL' 'MPL' 'CC BY-SA 3.0 Unported')
optdepends=('hunspell:	the spell checking libraries and apps')
source=("${pkgname}-${pkgver}.tar.gz"::"http://gitorious.org/dict-sr/hunspell-sr/archive-tarball/master")
sha1sums=('2a9920b1fb3e46618eaa01fd1f20e1790e38ab16')

build() {
 /bin/true
}

package() {
  cd "${srcdir}/dict-sr-hunspell-sr"
  install -dm755 ${pkgdir}/usr/share/hunspell
  install -m644 sr.dic sr.aff $pkgdir/usr/share/hunspell
  install -m644 sr-Latn.aff $pkgdir/usr/share/hunspell/sh.aff
  install -m644 sr-Latn.dic $pkgdir/usr/share/hunspell/sh.dic

  pushd $pkgdir/usr/share/hunspell/
  sr_aliases="sr_BA sr_RS"
  for lang in $sr_aliases; do
	ln -s sr.aff $lang.aff
	ln -s sr.dic $lang.dic
  done
  sh_aliases="sh_BA sh_RS"
  for lang in $sh_aliases; do
	ln -s sh.aff $lang.aff
	ln -s sh.dic $lang.dic
  done
  popd

  # docs
  install -dm755 ${pkgdir}/usr/share/doc/$pkgname
  install -m644 README*.txt $pkgdir/usr/share/doc/$pkgname

  # licenses
  install -D -m644 README.txt $pkgdir/usr/share/licenses/$pkgname/Copyright
  install -D -m644 README_sr.txt $pkgdir/usr/share/licenses/$pkgname/Copyright_sr
  install -D -m644 README-sr-Latn.txt $pkgdir/usr/share/licenses/$pkgname/Copyright_sh
}