# Contributions from KaOS: https://github.com/KaOSx/main/blob/master/gfxboot/PKGBUILD

pkgname=gfxboot
pkgver=4.5.6
_pkgver=1.1
pkgrel=1
arch=('x86_64')
license=(GPL)
install=gfxboot.install
pkgdesc="Graphical Boot Logo tool"
url="http://www.opensuse.org"
depends=('perl-html-parser' 'freetype2' 'cpio' 'nasm')
makedepends=('rpmextract')
source=("http://download.opensuse.org/source/distribution/13.2/repo/oss/suse/src/${pkgname}-${pkgver}-${_pkgver}.src.rpm"
	'gfxboot.html'
	'isolinux.patch')
options=(docs)
md5sums=('30435f328f89b4afee69d2f9f4b48db3'
         'f824c5bc2f716f8029677cae6956c1c7'
         '224289270f7ea288aaded3272a9c53f4')

prepare() {
  echo -e "\033[1;34m :: \033[1;39m Preparing ... please wait \033[1;0m"

  rpmextract.sh ${pkgname}-${pkgver}-${_pkgver}.src.rpm
  
  for i in $(find -name '*.tar.xz');do tar -Jxf $i;done
  mv -f themes ${pkgname}-${pkgver}/

  cd ${pkgname}-${pkgver}
  patch -p1 -i ${srcdir}/isolinux.patch
}

build() {
  cd ${pkgname}-${pkgver}
  make -s  
}
  
package() {
  cd ${pkgname}-${pkgver}
  make -s DESTDIR=$pkgdir installsrc 

  install -d -m 755 ${pkgdir}/usr/{sbin,share/man/man8,share/doc/gfxboot} 
  install -m 755 gfxboot gfxboot-compile gfxboot-font ${pkgdir}/usr/sbin 
  install -m 644 doc/gfxboot.8 ${pkgdir}/usr/share/man/man8/ 
  install -m 644 ../gfxboot.html ${pkgdir}/usr/share/doc/gfxboot 

}

# alternative source download
# source=(http://archpkg.rodp.net/src/${pkgname}-${pkgver}-${pkgrel}.src.rpm)