# maintainer: Neophytos Kolokotronis <tetris4ATgmailDOTcom>

pkgname=cmake
pkgver=3.4.0
_pkgver=3.4
pkgrel=1
pkgdesc="A cross-platform open-source make system"
arch=('x86_64')
license=('custom')
url="http://www.cmake.org"
depends=('curl' 'libarchive>=2.3.1' 'shared-mime-info' 'jsoncpp')
makedepends=('qt5-base' 'python3-sphinx')
install=${pkgname}.install
source=("http://www.cmake.org/files/v${_pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('a5b82bf6ace6c481cdb911fd5d372a302740cbefd387e05297cb37f7468d1cea')

prepare() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  # patch -Np1 < ${srcdir}/findfreetype.patch
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  
 # cmake -DBUILD_QtDialog=ON \
 #       -DCMAKE_INSTALL_PREFIX=/usr \
#	-DCMAKE_USE_SYSTEM_LIBRARIES=ON \
 #       . 

  # below version is for boostrapping cmake;
  # one can use it to break the recursive makedependency
  ./bootstrap --prefix=/usr \
    --mandir=/share/man \
    --docdir=/share/doc/cmake \
    --system-libs \
    --qt-gui \
    --qt-qmake=/usr/lib/qt5/bin/qmake \
    --parallel=$(/usr/bin/getconf _NPROCESSORS_ONLN)
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  vimpath="${pkgdir}/usr/share/vim/vimfiles"
  install -d "${vimpath}"/{help,indent,syntax}
  ln -s /usr/share/${pkgname}-${_pkgver}/editors/vim/cmake-help.vim "${vimpath}"/help/
  ln -s /usr/share/${pkgname}-${_pkgver}/editors/vim/cmake-indent.vim "${vimpath}"/indent/
  ln -s /usr/share/${pkgname}-${_pkgver}/editors/vim/cmake-syntax.vim "${vimpath}"/syntax/

  install -d "${pkgdir}"/usr/share/emacs/site-lisp/
  ln -s /usr/share/${pkgname}-${_pkgver}/editors/emacs/cmake-mode.el "${pkgdir}"/usr/share/emacs/site-lisp/

  install -Dm644 Copyright.txt \
    "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}