#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>


# NOTE: create symbolic link after install: sudo ln -sfv /usr/lib/liblzma.so /usr/lib/liblzma.so.0

pkgname=xz
pkgver=5.0.3
pkgrel=1
pkgdesc='Library and command line tools for XZ and LZMA compressed files'
arch=('i686' 'x86_64')
url='http://tukaani.org/xz/'
license=('GPL' 'LGPL' 'custom')
depends=('sh')
provides=('lzma' 'lzma-utils' 'xz-utils')
replaces=('lzma' 'lzma-utils' 'xz-utils')
conflicts=('lzma' 'lzma-utils' 'xz-utils')
options=('!libtool')
source=("http://tukaani.org/${pkgname}/${pkgname}-${pkgver}.tar.gz")
md5sums=('fefe52f9ecd521de2a8ce38c21a27574')

build() {
        cd ${srcdir}/${pkgname}-${pkgver}

        ./configure --prefix=/usr \
                --disable-rpath \
                --enable-werror
        make
}

check() {
        cd ${srcdir}/${pkgname}-${pkgver}
        make check
}

package() {
        cd ${srcdir}/${pkgname}-${pkgver}
        make DESTDIR=${pkgdir} install
        install -d -m755 ${pkgdir}/usr/share/licenses/xz/
        ln -sf /usr/share/doc/xz/COPYING ${pkgdir}/usr/share/licenses/xz/
        ln -sf /usr/share/licenses/common/GPL2/license.txt ${pkgdir}/usr/share/doc/xz/COPYING.GPLv2
}