# Platform Packages for Chakra, part of chakraos.org
#
# maintainer : almack[at]chakraos[dog]org>

pkgbase=php
pkgname=('php'
         'php-cgi'
         'php-apache'
         'php-fpm'
         'php-embed'
         'php-phpdbg'
         'php-pear'
         'php-enchant'
         'php-gd'
         'php-intl'
         'php-ldap'
         'php-mcrypt'
         'php-mssql'
         'php-odbc'
         'php-pgsql'
         'php-pspell'
         'php-snmp'
         'php-sqlite'
         'php-tidy'
         'php-xsl')
pkgver=5.6.12
pkgrel=1
arch=('x86_64')
license=('PHP')
url='http://www.php.net'
makedepends=('apache' 'imap' 'postgresql-libs' 'libldap' 'postfix'
             'sqlite3' 'unixodbc' 'net-snmp' 'libzip' 'enchant' 'file' 'freetds'
             'libmcrypt' 'tidyhtml' 'aspell' 'libltdl' 'libvpx' 'libxpm' 'gd' 'icu'
             'curl' 'libxslt' 'openssl' 'db' 'gmp' 'systemd')
source=("http://www.php.net/distributions/${pkgbase}-${pkgver}.tar.xz"
        'php.ini.patch'
        'apache.conf'
        'php-fpm.conf.in.patch'
        'logrotate.d.php-fpm'
        'php-fpm.service'
      	'php-fpm.tmpfiles')
md5sums=('f2cc602602eb2b121779f2c4b8bacaba'
         '39eff6cc99dae4ec3b52125e6229de7e'
         'dec2cbaad64e3abf4f0ec70e1de4e8e9'
         '16b5e2e4da59f15bea4c2db78a7bc8dc'
         '25bc67ad828e8147a817410b68d8016c'
         'cc2940f5312ba42e7aa1ddfab74b84c4'
         'c60343df74f8e1afb13b084d5c0e47ed')

prepare() {
  cd ${pkgbase}-${pkgver}

  # adjust paths
  patch -p0 -i "${srcdir}/php.ini.patch"
  patch -p0 -i "${srcdir}/php-fpm.conf.in.patch"
  # Just because our Apache 2.4 is configured with a threaded MPM by default does not mean we want to build a ZTS PHP.
  # Let's supress this behaviour and build a SAPI that works fine with the prefork MPM.
  sed '/APACHE_THREADED_MPM=/d' -i sapi/apache2handler/config.m4 -i configure
}

build() {
  local phpconfig=(
    --srcdir="${srcdir}/${pkgbase}-${pkgver}"
    --config-cache
    --prefix=/usr
    --sbindir=/usr/bin
    --sysconfdir=/etc/php
    --localstatedir=/var
    --with-layout=GNU
    --with-config-file-path=/etc/php
    --with-config-file-scan-dir=/etc/php/conf.d
    --disable-rpath
    --mandir=/usr/share/man
    --without-pear
  )

  local phpextensions=(
    --enable-bcmath=shared
    --enable-calendar=shared
    --enable-dba=shared
    --enable-exif=shared
    --enable-ftp=shared
    --enable-gd-native-ttf
    --enable-intl=shared
    --enable-mbstring
    --enable-opcache
    --enable-phar=shared
    --enable-posix=shared
    --enable-shmop=shared
    --enable-soap=shared
    --enable-sockets=shared
    --enable-sysvmsg=shared
    --enable-sysvsem=shared
    --enable-sysvshm=shared
    --enable-zip=shared
    --with-bz2=shared
    --with-curl=shared
    --with-db4=/usr
    --with-enchant=shared,/usr
    --with-fpm-systemd
    --with-freetype-dir=/usr
    --with-xpm-dir=/usr
    --with-gd=shared,/usr
    --with-gdbm
    --with-gettext=shared
    --with-gmp=shared
    --with-iconv=shared
    --with-icu-dir=/usr
    --with-imap-ssl
    --with-imap=shared
    --with-jpeg-dir=/usr
    --with-vpx-dir=/usr
    --with-ldap=shared
    --with-ldap-sasl
    --with-libzip
    --with-mcrypt=shared
    --with-mhash
    --with-mssql=shared
    --with-mysql-sock=/run/mysqld/mysqld.sock
    --with-mysql=shared,mysqlnd
    --with-mysqli=shared,mysqlnd
    --with-openssl=shared
    --with-pcre-regex=/usr
    --with-pdo-mysql=shared,mysqlnd
    --with-pdo-odbc=shared,unixODBC,/usr
    --with-pdo-pgsql=shared
    --with-pdo-sqlite=shared,/usr
    --with-pgsql=shared
    --with-png-dir=/usr
    --with-pspell=shared
    --with-snmp=shared
    --with-sqlite3=shared,/usr
    --with-tidy=shared
    --with-unixODBC=shared,/usr
    --with-xmlrpc=shared
    --with-xsl=shared
    --with-zlib
  )

  EXTENSION_DIR=/usr/lib/php/modules
  export EXTENSION_DIR
  PEAR_INSTALLDIR=/usr/share/pear
  export PEAR_INSTALLDIR

  cd ${pkgbase}-${pkgver}

  msg "php"
  mkdir -p "${srcdir}/build-php"
  cd "${srcdir}/build-php"
  ln -sf "../${pkgbase}-${pkgver}/configure"
  ./configure "${phpconfig[@]}" \
              --disable-cgi \
              --with-readline \
              --enable-pcntl \
              "${phpextensions[@]}"
  make

  msg "cgi and fcgi"
  # reuse the previous run; this will save us a lot of time
  cp -a "${srcdir}/build-php" "${srcdir}/build-cgi"
  cd "${srcdir}/build-cgi"
  ./configure "${phpconfig[@]}" \
              --disable-cli \
              --enable-cgi \
              "${phpextensions[@]}"
  make

  msg "apache"
  mkdir -p "${srcdir}/build-apache"
  cd "${srcdir}/build-apache"
  ln -sf "../${pkgbase}-${pkgver}/configure"
  ./configure "${phpconfig[@]}" \
              --disable-cli \
              --with-apxs2 \
              "${phpextensions[@]}"
  make

  msg "fpm"
  cp -a "${srcdir}/build-php" "${srcdir}/build-fpm"
  cd "${srcdir}/build-fpm"
  ./configure "${phpconfig[@]}" \
              --disable-cli \
              --enable-fpm \
              --with-fpm-user=http \
              --with-fpm-group=http \
              "${phpextensions[@]}"
  make

  msg "embed"
  cp -a "${srcdir}/build-php" "${srcdir}/build-embed"
  cd "${srcdir}/build-embed"
  ./configure "${phpconfig[@]}" \
              --disable-cli \
              --enable-embed=shared \
              "${phpextensions[@]}"
  make

  msg "phpdbg"
  cp -a "${srcdir}/build-php" "${srcdir}/build-phpdbg"
  cd "${srcdir}/build-phpdbg"
  ./configure "${phpconfig[@]}" \
              --disable-cli \
              --disable-cgi \
              --with-readline \
              --enable-phpdbg \
              "${phpextensions[@]}"
  make

  msg "pear"
  cp -a "${srcdir}/build-php" "${srcdir}/build-pear"
  cd "${srcdir}/build-pear"
  ./configure "${phpconfig[@]}" \
              --disable-cgi \
              --with-readline \
              --enable-pcntl \
              --with-pear \
              "${phpextensions[@]}"
  make
}

# check() {
#   cd ${srcdir}/build-php
#   make test
# }

package_php() {
  pkgdesc='An HTML-embedded scripting language'
  depends=('pcre' 'libxml2' 'curl' 'libzip')
  provides=('php-gmp' 'php-curl')
  conflicts=('php-gmp' 'php-curl')
  repclaces=('php-gmp' 'php-curl')
  backup=('etc/php/php.ini')

  cd "${srcdir}/build-php"
  make -j1 INSTALL_ROOT="${pkgdir}" install
  install -d -m755 "${pkgdir}/usr/share/pear"
  # install php.ini
  install -D -m644 "${srcdir}/${pkgbase}-${pkgver}/php.ini-production" "${pkgdir}/etc/php/php.ini"
  install -d -m755 "${pkgdir}/etc/php/conf.d/"

  # remove static modules
  rm -f "${pkgdir}/usr/lib/php/modules"/*.a
  # remove modules provided by sub packages
  rm -f "${pkgdir}/usr/lib/php/modules"/{enchant,gd,intl,ldap,mcrypt,mssql,odbc,pdo_odbc,pgsql,pdo_pgsql,pspell,snmp,sqlite3,pdo_sqlite,tidy,xsl}.so
  # remove empty directory
  rmdir ${pkgdir}/usr/include/php/include
}

package_php-cgi() {
  pkgdesc='CGI and FCGI SAPI for PHP'
  depends=('php' 'pcre' 'libxml2')

  install -D -m755 "${srcdir}/build-cgi/sapi/cgi/php-cgi" "${pkgdir}/usr/bin/php-cgi"
}

package_php-apache() {
  pkgdesc='Apache SAPI for PHP'
  depends=('php' 'apache')
  backup=('etc/httpd/conf/extra/php5_module.conf')

  install -D -m755 "${srcdir}/build-apache/libs/libphp5.so" "${pkgdir}/usr/lib/httpd/modules/libphp5.so"
  install -D -m644 "${srcdir}/apache.conf" "${pkgdir}/etc/httpd/conf/extra/php5_module.conf"
}

package_php-fpm() {
  pkgdesc='FastCGI Process Manager for PHP'
  depends=('php')
  backup=('etc/php/php-fpm.conf')
  install='php-fpm.install'

  install -D -m755 "${srcdir}/build-fpm/sapi/fpm/php-fpm" "${pkgdir}/usr/bin/php-fpm"
  install -D -m644 "${srcdir}/build-fpm/sapi/fpm/php-fpm.8" "${pkgdir}/usr/share/man/man8/php-fpm.8"
  install -D -m644 "${srcdir}/build-fpm/sapi/fpm/php-fpm.conf" "${pkgdir}/etc/php/php-fpm.conf"
  install -D -m644 "${srcdir}/logrotate.d.php-fpm" "${pkgdir}/etc/logrotate.d/php-fpm"
  install -d -m755 "${pkgdir}/etc/php/fpm.d"
  install -D -m644 "${srcdir}/php-fpm.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/php-fpm.conf"
  install -D -m644 "${srcdir}/php-fpm.service" "${pkgdir}/usr/lib/systemd/system/php-fpm.service"
}

package_php-embed() {
  pkgdesc='Embed SAPI for PHP'
  depends=('php' 'pcre' 'libxml2')

  install -D -m755 "${srcdir}/build-embed/libs/libphp5.so" "${pkgdir}/usr/lib/libphp5.so"
  install -D -m644 "${srcdir}/${pkgbase}-${pkgver}/sapi/embed/php_embed.h" "${pkgdir}/usr/include/php/sapi/embed/php_embed.h"
}

package_php-phpdbg() {
  pkgdesc='Interactive PHP debugger'
  depends=('php')

  install -D -m755 ${srcdir}/build-phpdbg/sapi/phpdbg/phpdbg ${pkgdir}/usr/bin/phpdbg
}

package_php-pear() {
  pkgdesc='PHP Extension and Application Repository'
  depends=('php')
  backup=('etc/php/pear.conf')

  cd "${srcdir}/build-pear"
  make install-pear INSTALL_ROOT="${pkgdir}"
  local i
  while read i; do
    [ ! -e "${i}" ] || rm -rf "${i}"
  done < <(find "${pkgdir}" -name '.*')
}

package_php-enchant() {
  pkgdesc='enchant module for PHP'
  depends=('php' 'enchant')

  install -D -m755 "${srcdir}/build-php/modules/enchant.so" "${pkgdir}/usr/lib/php/modules/enchant.so"
}

package_php-gd() {
  pkgdesc='GD module for PHP'
  depends=('php' 'gd')

  install -D -m755 "${srcdir}/build-php/modules/gd.so" "${pkgdir}/usr/lib/php/modules/gd.so"
}

package_php-intl() {
  pkgdesc='intl module for PHP'
  depends=('php' 'icu')

  install -D -m755 "${srcdir}/build-php/modules/intl.so" "${pkgdir}/usr/lib/php/modules/intl.so"
}

package_php-ldap() {
  pkgdesc='ldap module for PHP'
  depends=('php' 'libldap')

  install -D -m755 "${srcdir}/build-php/modules/ldap.so" "${pkgdir}/usr/lib/php/modules/ldap.so"
}

package_php-mcrypt() {
  pkgdesc='mcrypt module for PHP'
  depends=('php' 'libmcrypt' 'libltdl')

  install -D -m755 "${srcdir}/build-php/modules/mcrypt.so" "${pkgdir}/usr/lib/php/modules/mcrypt.so"
}

package_php-mssql() {
  pkgdesc='mssql module for PHP'
  depends=('php' 'freetds')

  install -D -m755 "${srcdir}/build-php/modules/mssql.so" "${pkgdir}/usr/lib/php/modules/mssql.so"
}

package_php-odbc() {
  pkgdesc='ODBC modules for PHP'
  depends=('php' 'unixodbc')

  install -D -m755 "${srcdir}/build-php/modules/odbc.so" "${pkgdir}/usr/lib/php/modules/odbc.so"
  install -D -m755 "${srcdir}/build-php/modules/pdo_odbc.so" "${pkgdir}/usr/lib/php/modules/pdo_odbc.so"
}

package_php-pgsql() {
  pkgdesc='PostgreSQL modules for PHP'
  depends=('php' 'postgresql-libs')

  install -D -m755 "${srcdir}/build-php/modules/pgsql.so" "${pkgdir}/usr/lib/php/modules/pgsql.so"
  install -D -m755 "${srcdir}/build-php/modules/pdo_pgsql.so" "${pkgdir}/usr/lib/php/modules/pdo_pgsql.so"
}

package_php-pspell() {
  pkgdesc='pspell module for PHP'
  depends=('php' 'aspell')

  install -D -m755 "${srcdir}/build-php/modules/pspell.so" "${pkgdir}/usr/lib/php/modules/pspell.so"
}

package_php-snmp() {
  pkgdesc='snmp module for PHP'
  depends=('php' 'net-snmp')

  install -D -m755 "${srcdir}/build-php/modules/snmp.so" "${pkgdir}/usr/lib/php/modules/snmp.so"
}

package_php-sqlite() {
  pkgdesc='sqlite3 module for PHP'
  depends=('php' 'sqlite3')

  install -D -m755 "${srcdir}/build-php/modules/sqlite3.so" "${pkgdir}/usr/lib/php/modules/sqlite3.so"
  install -D -m755 "${srcdir}/build-php/modules/pdo_sqlite.so" "${pkgdir}/usr/lib/php/modules/pdo_sqlite.so"
}

package_php-tidy() {
  pkgdesc='tidy module for PHP'
  depends=('php' 'tidyhtml')

  install -D -m755 "${srcdir}/build-php/modules/tidy.so" "${pkgdir}/usr/lib/php/modules/tidy.so"
}

package_php-xsl() {
  pkgdesc='xsl module for PHP'
  depends=('php' 'libxslt')

  install -D -m755 "${srcdir}/build-php/modules/xsl.so" "${pkgdir}/usr/lib/php/modules/xsl.so"
}

# vim:set ts=2 sw=2 et: