# Contributor: Andrea Scarpino <andrea@archlinux.org>

source ../frameworks.conf

pkgname=plasma-framework
pkgver=${KFVersion}
pkgrel=1
pkgdesc='Plasma library and runtime components based upon KF5 and Qt5'
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/playground/libs/plasma-framework'
license=('LGPL')
depends=('qt5-quickcontrols' 'kidletime' 'kitemmodels' 'threadweaver'
         'kwallet' 'kdeclarative' 'kunitconversion'
         'kross' 'kdnssd' 'kinit'
         'kactivities' 'kdoctools')
makedepends=('extra-cmake-modules' 'git' 'qt5-tools')
optdepends=('kde-workspace: provide a Plasma shell')
options=("debug")
source=("${KFServer}/${pkgver}/${pkgname}-${pkgver}.tar.xz")
sha256sums=( $(getSum ${pkgname}) )

prepare() {
  mkdir -p build
}

build() {

  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=${KFBuildType} \
    -DCMAKE_INSTALL_PREFIX=${KFInstallPrefix} \
    -DLIB_INSTALL_DIR=lib 
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}