# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=attica-qt5
_pkgname=attica
pkgver=5.46.0
pkgrel=1
arch=('x86_64')
url='https://projects.kde.org/projects/kdesupport/${_pkgname}'
pkgdesc='A Qt5 library that implements the Open Collaboration Services API'
license=('LGPL')
depends=("qt5-base")
makedepends=("extra-cmake-modules>=${pkgver}")
checkdepends=("cmake")
options=("debug")
_url="https://download.kde.org/stable/frameworks/${pkgver%.*}/${_pkgname}-${pkgver}.tar.xz"
source=(${_url}{,.sig})
sha256sums=($(curl "$_url.sha256" | cut -c-64)
            SKIP)
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${_pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_SYSCONFDIR=/etc \
    -DKDE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON

  make
}

# check() {
#   cd build
#   make test
# }

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}