# Software packages for Chakra, part of www.chakra-project.org
#
# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Josh Taylor <joshtaylor.mail@gmail.com>
#               simo <simo@archlinux.org>
#               Douglas Soares de Andrade <douglas@archlinux.org>
#               Daniel J Griffiths <ghost1227@archlinux.us>

pkgbase=python-opengl
pkgname=('python3-opengl' 'python2-opengl')
pkgver=3.1.0
pkgrel=1
pkgdesc="The cross platform Python binding to OpenGL and related APIs"
arch=('any')
license=('BSD')
url="http://pyopengl.sourceforge.net"
makedepends=('freeglut' 'python2-setuptools' 'python3-setuptools')
source=("http://pypi.python.org/packages/source/P/PyOpenGL/PyOpenGL-${pkgver}.tar.gz"
        'LICENSE')
md5sums=('0de021941018d46d91e5a8c11c071693'
         '0b53c508a63e5dbaf44cdfb0fa103b3a')


prepare() {
    cp -r PyOpenGL-${pkgver} python3-PyOpenGL-${pkgver}
}

package_python2-opengl() {
    depends=('python2' 'freeglut')
    conflicts=('pyopengl' 'python-pyopengl' 'python-opengl')
    replaces=('pyopengl' 'python-pyopengl' 'python-opengl')
    provides=('pyopengl' 'python-pyopengl' 'python-opengl')

    cd PyOpenGL-${pkgver}
    python2 setup.py install --root="${pkgdir}" --optimize=1
    install -Dm644 "${srcdir}/LICENSE" \
        "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    # Fix the shebang
    sed -i 's|#!/usr/bin/env python|#!/usr/bin/python2|' \
      "${pkgdir}"/usr/lib/python2.7/site-packages/OpenGL/Tk/__init__.py
    sed -i 's|#! /usr/bin/env python|#!/usr/bin/python2|' \
      "${pkgdir}"/usr/lib/python2.7/site-packages/OpenGL/arrays/{_,}buffers.py
}

package_python3-opengl() {
    depends=('python3' 'freeglut')
 
    cd python3-PyOpenGL-${pkgver}
    python3 setup.py install --root="${pkgdir}" --optimize=1
    install -Dm644 "${srcdir}/LICENSE" \
        "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    # Fix the shebang
    sed -i 's|#!/usr/bin/env python|#!/usr/bin/python3|' \
      "${pkgdir}"/usr/lib/python3.4/site-packages/OpenGL/Tk/__init__.py
    sed -i 's|#! /usr/bin/env python|#!/usr/bin/python3|' \
      "${pkgdir}"/usr/lib/python3.4/site-packages/OpenGL/arrays/{_,}buffers.py
}