#contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/kde-cli-tools

pkgname=kde-cli-tools
pkgver=5.13.5
pkgrel=1
pkgdesc="Tools based on KDE Frameworks 5 to better interact with the system"
arch=('x86_64')
url='https://projects.kde.org/projects/kde/workspace/kde-cli-tools'
license=('LGPL')
depends=(kdesu kcmutils kinit kactivities plasma-workspace)
makedepends=(extra-cmake-modules python3 kdoctools)
checkdepends=("cmake")
groups=('plasma')
options=("debug")
source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('6768ee62ee1df6e1d441dd41747d6a6eab781cbb84180fc12f7591682590f6b7'
             'SKIP' )
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@" \
    -DPYHTON_EXECUTABLE=/usr/bin/python3
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install

  # conflicts with kdebase-runtime
  rm -r "$pkgdir"/usr/share/man

  # link some useful binaries
  ln -sf /usr/lib/kf5/kdesu ${pkgdir}/usr/bin/kdesu
  ln -sf /usr/lib/kf5/kdeeject ${pkgdir}/usr/bin/kdeeject
}