# maintainer tetris4@gmail.com
# contributions from: https://www.archlinux.org/packages/community/x86_64/bbswitch/

_extramodules=extramodules-4.2-CHAKRA
_kver="$(cat /usr/lib/modules/${_extramodules}/version)"
_kernelver=4.2.6

pkgname=bbswitch
pkgver=0.8
pkgrel=20
pkgdesc="kernel module allowing to switch dedicated graphics card on Optimus laptops"
arch=('x86_64')
url=("http://github.com/Bumblebee-Project/bbswitch")
license=('GPL')
install=bbswitch.install
depends=("linux=${_kernelver}")
makedepends=("linux-headers=${_kernelver}")
source=("https://github.com/Bumblebee-Project/bbswitch/archive/v${pkgver}.tar.gz")
md5sums=('5b116b31ace3604ddf9d1fc1f4bc5807')

prepare() {
  #automatically update bbswitch.install
  sed -i -e "s/EXTRAMODULES='.*'/EXTRAMODULES='${_extramodules}'/" "${startdir}/bbswitch.install"
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make KDIR=/usr/src/linux-${_kver}
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  msg2 "Building module for $_kver..."

  # KDIR is necessary even when cleaning
  #make KDIR=/usr/src/linux-${_kver} clean
  install -Dm644 bbswitch.ko $pkgdir/usr/lib/modules/${_extramodules}/bbswitch.ko
  gzip "${pkgdir}/usr/lib/modules/${_extramodules}/bbswitch.ko"
}