pkgname=man-pages
pkgver=4.16
_posixver=2013-a
pkgrel=1
pkgdesc="Linux man pages"
arch=('any')
license=('GPL')
url="http://man7.org/linux/man-pages/index.html"
groups=('base')
depends=()
source=(http://www.kernel.org/pub/linux/docs/man-pages/$pkgname-$pkgver.tar.xz
        http://www.kernel.org/pub/linux/docs/man-pages/man-pages-posix/$pkgname-posix-${_posixver}.tar.xz)
sah256sums=('3401eb0020c56639070d199c3e59a4f8'
         '7c78aff03c0a6767ba483d34f19e4b09')

build() {
  cd ${srcdir}/$pkgname-$pkgver
  
  # move the posix pages
  mkdir -p ${srcdir}/$pkgname-$pkgver/man0
  for sect in 0 1 3; do
    sed -i "/^\.so /s/man${sect}p/man$sect/" "${srcdir}/$pkgname-posix-${_posixver}/man${sect}p"/*
    mv -iv "${srcdir}/$pkgname-posix-${_posixver}/man${sect}p"/* "${srcdir}/$pkgname-$pkgver/man$sect/"
  done
}

package() {
  cd ${srcdir}/$pkgname-$pkgver

  make prefix=${pkgdir}/usr install

  # posix pages have a custom license
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 ${srcdir}/$pkgname-posix-${_posixver}/POSIX-COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/POSIX-COPYRIGHT"

  cd ${pkgdir}/usr/share/man
  # these are included in coreutils
  rm -f man1/{chgrp,chmod,chown,cp,dir,dd}.1
  rm -f man1/{df,dircolors,du,install,ln,ls}.1
  rm -f man1/{mkdir,mkfifo,mknod,mv,rm,rmdir}.1
  rm -f man1/{touch,vdir}.1
  # this is included in shadow
  rm -f man5/passwd.5
  rm -f man3/getspnam.3
  # this is included in diffutils
  rm -f man1/diff.1
  # this is included in xf86-input-mouse
  rm -f man4/mouse.4
  # this is included in attr
  rm -f man5/attr.5 
  # included in lirc
  rm -f man4/lirc.4
  # included in keyutils
  rm -f man7/{keyrings.7,persistent-keyring.7,process-keyring.7,session-keyring.7,thread-keyring.7,user-keyring.7,user-session-keyring.7}
  # included in tzdata
  rm -f man5/tzfile.5 man8/{tzselect,zdump,zic}.8
}
md5sums=('ad9f1ff81276fe8d90d077484d6d4b5e'
         '825fde78e6fddd02426ecdd50e2cbe0d')