# Maintainer: Neophytos Kolokotronis <tetris4 AT gmail DOT com>

# Source global configuration
source ../linux-lts.conf

pkgname=ndiswrapper-lts
_pkgname=ndiswrapper
pkgver=1.61
pkgrel=4
pkgdesc="Module for NDIS (Windows Network Drivers) drivers supplied by vendors. For linux-lts."
license=('GPL')
arch=('x86_64')
url="http://ndiswrapper.sourceforge.net"
install="ndiswrapper.install"
depends=("linux-lts=${_kernelver}")
makedepends=("linux-lts-headers=${_kernelver}")
source=("http://downloads.sourceforge.net/sourceforge/ndiswrapper/ndiswrapper-$pkgver.tar.gz")
sha1sums=('213854ca8a83f9b5972db8fa873d346124e4bcb5')

prepare() {
  cd "$srcdir/$_pkgname-$pkgver" 
  #patch -p1 -i ../ndiswrapper-1.59.patch
  sed -i "/modinfo/s/s/usr\//" driver/Makefile
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"        
  make -C driver KVERS_UNAME=${_kver}
  make -C utils
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"   

  make sbindir=usr/sbin usrsbindir=usr/bin KBUILD=${_rootOfSourceTree} INST_DIR="usr/lib/modules/$_extramodules" \
        KVERS=$_kver DESTDIR="$pkgdir/" install

  sed -i -e "s/EXTRAMODULES='.*'/EXTRAMODULES='${_extramodules}'/" \
          "${startdir}/ndiswrapper.install"
}