# maintainer Manuel Tortosa

# Note: you have to rebuild those pkgs
# Core: repo-clean
# Platform: akonadi (exempi uses boost just as makedep)
# Desktop: kdeedu (kdenetwork, kdepimlibs, kdepim, kdesdk and koffice using boost just as makedep)
 
pkgbase=boost
pkgname=('boost-libs' 'boost')
pkgver=1.55.0
_boostver=${pkgver//./_}
pkgrel=2
pkgdesc="Free peer-reviewed portable C++ source libraries"
arch=('x86_64')
url="http://www.boost.org/"
license=('custom')
makedepends=('icu' 'python2' 'python3' 'bzip2' 'zlib' 'openmpi') 
source=("http://downloads.sourceforge.net/${pkgbase}/${pkgbase}_${_boostver}.tar.gz"
        # upstream patches
        log_fix_dump_avx2.patch)
md5sums=('93780777cfbf999a600f62883bd54b17'
         '2d8c2a83421afacda0ff0192c68b2c17')
#options=("!makeflags")
license=('custom')

_stagedir="${srcdir}/stagedir"

prepare() {
   cd "${srcdir}/${pkgbase}_${_boostver}"

   patch -Np0 < ${srcdir}/log_fix_dump_avx2.patch

   # Add an extra python version. This does not replace anything and python 2.x need to be the default.
   echo "using python : 3.4 : /usr/bin/python3 : /usr/include/python3.4m : /usr/lib ;" >> ./tools/build/v2/user-config.jam
   # Support for OpenMPI
   echo "using mpi ;" >> ./tools/build/v2/user-config.jam

   ./bootstrap.sh --with-toolset=gcc --with-icu 

}

build() {
   cd "${srcdir}/${pkgbase}_${_boostver}"
   local JOBS="$(sed -e 's/.*\(-j *[0-9]\+\).*/\1/' <<< ${MAKEFLAGS})"

   ./bootstrap.sh --with-toolset=gcc --with-icu --with-python=/usr/bin/python2


   _bindir="bin.linuxx86_64"

   install -d -m 755 "${_stagedir}"/bin
   install tools/build/v2/engine/${_bindir}/b2 "${_stagedir}"/bin/b2


   pushd tools
   for _tool in bcp inspect quickbook compiler_status process_jam_log wave; do
      "${_stagedir}"/bin/b2 --toolset=gcc cflags="${CPPFLAGS} ${CFLAGS} -std=gnu++11 -O3" linkflags="${LDFLAGS}" $_tool
   done
   "${_stagedir}"/bin/b2 --toolset=gcc cflags="${CPPFLAGS} ${CFLAGS} -O3" linkflags="${LDFLAGS}" library_status
   popd
   cp -a dist/bin/* "${_stagedir}"/bin

   # boostbook is needed by quickbook
   install -dm755 "${_stagedir}"/share/boostbook
   cp -a tools/boostbook/{xsl,dtd} "${_stagedir}"/share/boostbook/

   # default "minimal" install: "release link=shared,static
   # runtime-link=shared threading=single,multi"
   # --layout=tagged will add the "-mt" suffix for multithreaded libraries
   # and installs includes in /usr/include/boost.
   # --layout=system no longer adds the -mt suffix for multi-threaded libs.
   # install to ${_stagedir} in preparation for split packaging
   "${_stagedir}"/bin/b2 \
      variant=release \
      debug-symbols=off \
      threading=multi \
      runtime-link=shared \
      link=shared,static \
      toolset=gcc \
      python=2.7 \
      cflags="${CPPFLAGS} ${CFLAGS} -O3" linkflags="${LDFLAGS}" \
      --layout=system \
      --prefix="${_stagedir}" \
      ${JOBS} \
      install
}

package_boost() {
   pkgdesc="Free peer-reviewed portable C++ source libraries - Development"
   depends=("boost-libs=${pkgver}")
   optdepends=('python2: for python2 bindings'
               'python3: for python3 bindings'
               'boost-build: to use boost jam for building your project.')
   options=('staticlibs')


   install -dm755 "${pkgdir}"/usr
   cp -a "${_stagedir}"/{bin,include,share} "${pkgdir}"/usr

   install -d "${pkgdir}"/usr/lib
   find "${_stagedir}"/lib -name \*.a -exec mv {} "${pkgdir}"/usr/lib \;

   install -Dm644 "${srcdir}/"${pkgbase}_${_boostver}/LICENSE_1_0.txt \
      "${pkgdir}"/usr/share/licenses/boost/LICENSE_1_0.txt

   ln -s /usr/bin/b2 ${pkgdir}/usr/bin/bjam || msg "faulty"
}

package_boost-libs() {
   pkgdesc="Free peer-reviewed portable C++ source libraries - Runtime"
   depends=('bzip2' 'zlib' 'icu')
   optdepends=('openmpi: for mpi support')

   install -d -m 755 "${pkgdir}"/usr
   cp -a "${_stagedir}"/lib "${pkgdir}"/usr

   install -D -m 644 "${srcdir}/"${pkgbase}_${_boostver}/LICENSE_1_0.txt \
      "${pkgdir}"/usr/share/licenses/boost-libs/LICENSE_1_0.txt
}