# Maintainer: abveritas@chakra-project.org

pkgname=pulseaudio
pkgdesc="A featureful, general-purpose sound server"
pkgver=3.0
pkgrel=5
arch=('x86_64')
url="http://pulseaudio.org/"
license=('GPL' 'LGPL')
depends=('dbus-core' 'xcb-util' 'libasyncns' 'libcap' 'libxtst' 'libsm'
         'libsamplerate' 'json-c' 'rtkit' 'libltdl' 'speex' 'tdb'
         'fftw' 'orc' 'webrtc-audio-processing' 'systemd>=195' 'sbc')
makedepends=('attr' 'libltdl' 'avahi' 'bluez' 'intltool' 'jack' 'lirc-utils' 'openssl'
             'libsndfile' 'pkgconfig' 'sh')
optdepends=('avahi: zeroconf support'
            'bluez: bluetooth support'
            'jack: jack support'
            'lirc-utils: infra-red support'
            'openssl: RAOP support')
backup=(etc/pulse/{daemon.conf,default.pa,system.pa})
install="pulseaudio.install"
provides=("libpulse=${pkgver}")
replaces=('libpulse')
conflicts=('libpulse')
options=(!emptydirs !libtool !makeflags)
#source=("http://freedesktop.org/software/${pkgname}/releases/${pkgname}-${pkgver}.tar.xz")
source=("http://chakra.sourceforge.net/sources/${pkgname}/${pkgname}.tar.xz")
md5sums=('10049e1fa0577be38ba04d8bab159fd1')

build() {
  cd "${srcdir}/${pkgname}"

  ./autogen.sh --prefix=/usr \
               --sysconfdir=/etc \
               --libexecdir=/usr/lib \
               --localstatedir=/var \
               --with-udev-rules-dir=/usr/lib/udev/rules.d \
               --with-database=tdb \
               --disable-rpath \
               --disable-default-build-tests

  make
}

package() {
  cd "${srcdir}/${pkgname}"
  make DESTDIR="${pkgdir}" install

  # Disable cork-request module, can result in e.g. media players unpausing
  # when there's a Skype call incoming
  sed -e 's|/usr/bin/pactl load-module module-x11-cork-request|#&|' \
      -i "${pkgdir}/usr/bin/start-pulseaudio-x11"

  # Python fix
  sed -i '1s:python$:&2:' "${pkgdir}/usr/bin/qpaeq"

  rm "${pkgdir}/etc/dbus-1/system.d/pulseaudio-system.conf"
  rm "${pkgdir}/etc/xdg/autostart/pulseaudio.desktop"
  rm "${pkgdir}/etc/xdg/autostart/pulseaudio-kde.desktop"
  
}