#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer abveritas[at]chakra-project[dot]org>

pkgbase=qscintilla
pkgname=(qscintilla python-qscintilla)
pkgver=2.7
pkgrel=1
license=('GPL')
arch=('x86_64')
url="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
makedepends=('pyqt' 'chrpath')
source=("http://downloads.sourceforge.net/pyqt/QScintilla-gpl-${pkgver}.tar.gz"
        'configure.py-objdir-support.diff')
md5sums=('a3857d75a2b332e0460131e0aa4cc4b5'
         '8cf9c06252e2f11ab00e62848e322fd3')

build() {
    cd $srcdir/QScintilla-gpl-$pkgver
    patch -p1 -i "${srcdir}/configure.py-objdir-support.diff"

    cd Qt4Qt5
    qmake qscintilla.pro
    make
    
    cd ../designer-Qt4
    qmake designer.pro INCLUDEPATH+=../Qt4Qt5 QMAKE_LIBDIR+=../Qt4Qt5
    make

    cd ../Python
    python2 configure.py -n ../Qt4Qt5/ -o ../Qt4Qt5 -c -p 4
    make
}

package_qscintilla() {
    pkgdesc="A port to Qt of Neil Hodgson's Scintilla C++ editor class"
    provides=('qscintilla2')
    conflicts=('qscintilla2')
    replaces=('qscintilla2')
    depends=('qt')

    cd ${srcdir}/QScintilla-gpl-${pkgver}/Qt4Qt5
    make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install

    cd ${srcdir}/QScintilla-gpl-${pkgver}/designer-Qt4
    make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install
}

package_python-qscintilla() {
    pkgdesc="Python bindings for QScintilla2"
    conflicts=('python-qscintilla2')
    replaces=('python-qscintilla2')
    depends=('qscintilla' 'pyqt')

    cd "${srcdir}/QScintilla-gpl-${pkgver}/Python"
    make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install
}