#
# Platform Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=farsight2
pkgver=0.0.28
pkgrel=1
pkgdesc="Audio/Video conference software for Instant Messengers"
arch=('i686' 'x86_64')
url="http://farsight.freedesktop.org"
license=('LGPL')
depends=('libnice' 'gstreamer0.10-base-plugins' 'gstreamer0.10-good' 'gstreamer0.10-bad' 'gstreamer0.10-python' 'python2' 'pygobject>=2.16.0')
optdepends=('gstreamer0.10-ugly-plugins: h264 codec')
options=('!libtool' '!emptydirs')
source=(http://farsight.freedesktop.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.gz)
md5sums=('38767e775067270754a32aaf8e3a7db1')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  sed -i -e 's#python-config#python2-config#' python/Makefile.in
  # this makefile is broken
  sed -i -e 's#        #        #' docs/libs/Makefile.in

  ./configure --prefix=/usr \
      --with-package-name='Chakra Linux farsight2 package' \
      --with-package-origin='http://chakra-project.org' \
      --disable-static -disable-valgrind --disable-debug
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR=${pkgdir} install || return 1
}