# Platform Packages for Chakra, part of chakra-project.org
# Maintainer: Neophytos Kolokotronis <tetris4@gmail.com>
# Contributions from AUR: https://aur.archlinux.org/packages/hf/hfsprogs/PKGBUILD

pkgname=hfsprogs
pkgver=332.25
pkgrel=2
pkgdesc="HFS/HFS+ user space utils" 
arch=('x86_64')
depends=('libbsd')
license=('custom:APSL')
url="http://www.opensource.apple.com/"
source=(http://ftp.de.debian.org/debian/pool/main/h/hfsprogs/hfsprogs_332.25.orig.tar.gz \
	http://ftp.de.debian.org/debian/pool/main/h/hfsprogs/hfsprogs_332.25-10.debian.tar.gz \
        license
	makefile.patch)
md5sums=('261c3de5ec0dcf5244e3f60d79c1d6f1'
	 'f3d04a0380ecfbb7751abed53fb5525d'
         '771f0a6036a80d929c07df49f9a3d909'
	 'e2429944c0192d817c700b8f0dffce6e')

build() {
    cd $srcdir/diskdev_cmds-${pkgver}
    patch -Np1 -i $srcdir/debian/patches/00-create_makefiles.patch
    patch -Np1 -i $srcdir/debian/patches/10-linux_specific_code.patch
    patch -Np1 -i $srcdir/debian/patches/20-apple_specific_files.patch
    patch -Np1 -i $srcdir/debian/patches/25-64-bit-fix.patch
    patch -Np1 -i $srcdir/debian/patches/30-formatting_strings.patch
    patch -Np1 -i $srcdir/debian/patches/40-printf_types.patch
    patch -Np1 -i $srcdir/debian/patches/50-typo-new_fs-manpage.diff
    patch -Np1 -i $srcdir/debian/patches/60-hfs-wrapper-boot-in-usr-share.diff
    patch -Np1 -i $srcdir/debian/patches/70-diskdev_cmds_system_check-332.14.patch
    patch -Np1 -i $srcdir/debian/patches/80-fix_manpages.patch
    patch -Np1 -i $srcdir/debian/patches/90-rename_dprintf.patch
    patch -Np1 -i $srcdir/debian/patches/91-remove-nils.patch
    patch -Np1 -i $srcdir/debian/patches/92-fix-types.patch
    patch -Np1 -i $srcdir/debian/patches/hfsplus-tools-332.14-fix-uuid.patch
    patch -Np0 -i "${srcdir}/makefile.patch"
    make -f Makefile.lnx
}

package() {
    cd $srcdir/diskdev_cmds-${pkgver}
    install -d -m 755 "$pkgdir/usr/share/hfsprogs"
    install -m 644 newfs_hfs.tproj/hfsbootdata.img "$pkgdir/usr/share/hfsprogs/hfsbootdata"
    install -D -m755 newfs_hfs.tproj/newfs_hfs "$pkgdir/sbin/mkfs.hfsplus"
    install -D -m755 fsck_hfs.tproj/fsck_hfs "$pkgdir/sbin/fsck.hfsplus"
    install -D -m644 $startdir/src/license "$pkgdir/usr/share/licenses/hfsprogs/APSL"
    install -d -m 755 "$pkgdir/usr/share/man/man8/"
    install -m 644 newfs_hfs.tproj/newfs_hfs.8 "$pkgdir/usr/share/man/man8/mkfs.hfsplus.8"
    install -m 644 fsck_hfs.tproj/fsck_hfs.8 "$pkgdir/usr/share/man/man8/fsck.hfsplus.8"
}