#
# Platform Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=splashy
pkgver=0.3.13
pkgrel=1
pkgdesc="A next-generation user-space boot splashing system for Linux systems without depending on initscripts-splashy"
arch=('i686' 'x86_64')
url="http://splashy.alioth.debian.org/"
license=('GPL')
makedepends=('pkg-config')
depends=('file' 'glib2' 'directfb' 'initscripts')
options=('!libtool' '!distcc' '!makeflags')
install=splashy.install
source=(https://alioth.debian.org/frs/download.php/2691/splashy-0.3.13.tar.gz
	splashy.initcpio_install
	splashy.initcpio_hook
	splashy.install
	splashy-functions
	splash-initscripts
	splash.conf
	splashy_video.c.patch)
md5sums=('03b7ee4f31c56ee61463772f74bad8a0'
'd2b7123d410e8bb62964f514a889c401'
'f2d1b7ca4560a2888b08c5580dc8afae'
'0a9c7e9a3c0dd0f6fa7443d55eb71b3e'
'91972fc154635806923befe3a70a1299'
'efb94b087c588540c8c50b1c5a00f706'
'fe6da7a9242aca91779e165979bb7e3d'
'2c827c217d6f30d5e7e982fa40c5564e') 

build() {
	cd splashy-${pkgver}

	patch -Np1 -i ${srcdir}/splashy_video.c.patch

	./configure --prefix=/usr --libdir=/usr/lib --sysconfdir=/etc --sbindir=/sbin --datarootdir=/usr/share --mandir=/usr/share/man --includedir=/usr/include
	make
}

package() {
	cd splashy-${pkgver}
	make DESTDIR=${pkgdir} install

	# Remove unnecessary files
	rm -rf ${pkgdir}/etc/{console-tools,default,init.d,lsb-base-logging.sh}
	rm -rf ${pkgdir}/usr/share/initramfs-tools

	install -D -m644 ${srcdir}/splashy.initcpio_install ${pkgdir}/lib/initcpio/install/splashy
	install -D -m644 ${srcdir}/splashy.initcpio_hook ${pkgdir}/lib/initcpio/hooks/splashy
	install -D -m644 ${srcdir}/splashy-functions ${pkgdir}/etc/rc.d/splashy-functions

	install -D -m644 ${srcdir}/splash-initscripts ${pkgdir}/etc/rc.d/functions.d/splash
	install -D -m644 ${srcdir}/splash.conf ${pkgdir}/etc/splash.conf

	sed -e 's|>/etc/splashy/themes<|>/usr/share/splashy/themes<|' -i ${pkgdir}/etc/splashy/config.xml
}