#
# Platform Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=jack
pkgver=0.121.3
pkgrel=2
pkgdesc="A low-latency audio server"
arch=('i686' 'x86_64')
license=('GPL2' 'custom:LGPL2')
depends=('readline' 'libsamplerate')
makedepends=('doxygen' 'celt')
url="http://jackit.sourceforge.net/"
backup=(etc/conf.d/jack-audio-connection-kit)
options=('!libtool')
provides=("jack-audio-connection-kit=${pkgver}")
replaces=('jack-audio-connection-kit')
install=$pkgname.install
source=("http://jackaudio.org/downloads/jack-audio-connection-kit-$pkgver.tar.gz"
        "99-realtime.conf"
        "40-hpet-permissions.rules")
md5sums=('35f470f7422c37b33eb965033f7a42e8'
         'bb312fa74956066046d6a599ac623c98'
         '6a1017041c024cea57da9bd726b664d7')

build() {
  cd "${srcdir}/jack-audio-connection-kit-${pkgver}"

  ./configure --prefix=/usr \
              --libdir=/usr/lib
  make
}

package() {
  cd "${srcdir}/jack-audio-connection-kit-${pkgver}"

  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/99-realtime.conf" \
    "$pkgdir/etc/security/limits.d/99-realtime.conf"

  install -Dm644 "$srcdir/40-hpet-permissions.rules" \
    "$srcdir/lib/udev/rules.d/40-hpet-permissions.rules"
}