# Arch Contributor: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-hypothesis
pkgname=('python3-hypothesis' 'python2-hypothesis')
pkgver=3.33.0
pkgrel=1
pkgdesc="Advanced Quickcheck style testing library for Python"
arch=('any')
license=('MPL')
url="https://hypothesis.readthedocs.org"
makedepends=('python3-setuptools' 'python2-setuptools' 'python2-enum34')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/HypothesisWorks/hypothesis-python/archive/$pkgver.tar.gz")
sha512sums=('3e89fa183381f2df556016ff4af17d2731685b019aed74d5f8dccd53ad262dce107f83f105b7e950a579ef247cc9b8336f15ee321292522118fa4c3487a21138')

prepare() {
  cp -a hypothesis-python-$pkgver{,-py2}

  rm -r hypothesis-python-$pkgver/tests/py2
  rm -r hypothesis-python-$pkgver-py2/tests/py3

  export LC_CTYPE=en_US.UTF-8
}

build() {
  cd "$srcdir"/hypothesis-python-$pkgver
  python3 setup.py build

  cd "$srcdir"/hypothesis-python-$pkgver-py2
  python2 setup.py build
}

package_python3-hypothesis() {
  depends=('python3')

  cd hypothesis-python-$pkgver
  python3 setup.py install --root="$pkgdir" --optimize=1
}

package_python2-hypothesis() {
  depends=('python2-enum34')

  cd hypothesis-python-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
}