#
# Platform Packages for Chakra, part of chakra-project.org
#
# maintainer abveritas[at]chakra-project[dot]org>

pkgname=pyqt
pkgver=4.9.4
pkgrel=1
pkgdesc="A set of Python bindings for the Qt toolkit"
arch=('i686' 'x86_64')
url="http://riverbankcomputing.co.uk/software/pyqt/intro"
license=('GPL')
depends=('sip' 'qtwebkit' 'dbus-python')
makedepends=('phonon' 'python-opengl' 'qt-assistant-compat')
optdepends=('phonon: enable audio and video in PyQt applications'
        'python-opengl: enable OpenGL 3D graphics in PyQt applications'
        'qscintilla: QScintilla API'
        'qt-assistant-compat: add PyQt online help in Qt Assistant')
provides=('pyqt4')
replaces=('pyqt4')
conflicts=('pyqt4')
source=("http://sourceforge.net/projects/pyqt/files/PyQt4/PyQt-${pkgver}/PyQt-x11-gpl-${pkgver}.tar.gz"
        'fix-pyuic4.patch')
md5sums=('a0b6a820633366365af5124ddbd059c7'
         '097651aea0bafded5abdfd6d62afd2ad')

build() {
  cd "${srcdir}"/PyQt-x11-gpl-${pkgver}
  patch -p1 -i "${srcdir}"/fix-pyuic4.patch
  cd ..

  cd ${srcdir}/PyQt-x11-gpl-${pkgver}

  python2 configure.py \
    --confirm-license \
    -v /usr/share/sip \
    --qsci-api

  # Thanks Gerardo for the rpath fix
  find -name 'Makefile' | xargs sed -i 's|-Wl,-rpath,/usr/lib||g;s|-Wl,-rpath,.* ||g'

  make
}

package(){
  cd ${srcdir}/PyQt-x11-gpl-${pkgver}
  # INSTALL_ROOT is needed for the QtDesigner module, the other Makefiles use DESTDIR
  make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install
}