mirror of
https://gitdl.cn/https://github.com/chakralinux/core.git
synced 2025-02-10 14:34:36 +08:00
125 lines
4.2 KiB
Bash
125 lines
4.2 KiB
Bash
# Maintainer: Manuel Tortosa
|
|
|
|
pkgbase=pulseaudio
|
|
pkgname=(pulseaudio libpulse)
|
|
pkgdesc="A featureful, general-purpose sound server"
|
|
pkgver=3.99.2
|
|
pkgrel=1
|
|
arch=('x86_64')
|
|
url="http://www.freedesktop.org/wiki/Software/PulseAudio"
|
|
license=(GPL LGPL)
|
|
makedepends=(libasyncns libcap attr libxtst libsm libsamplerate libtool rtkit
|
|
speex tdb systemd dbus avahi bluez intltool jack sbc
|
|
lirc-utils openssl fftw orc json-c webrtc-audio-processing)
|
|
options=(!emptydirs !libtool)
|
|
source=(http://freedesktop.org/software/$pkgbase/releases/$pkgbase-$pkgver.tar.xz)
|
|
sha256sums=('165dc52760377af939d06b49a170ef65c4b844b22020b57c69c9bd6fe56c781c')
|
|
|
|
build() {
|
|
cd $pkgbase-$pkgver
|
|
|
|
./configure --prefix=/usr \
|
|
--sysconfdir=/etc \
|
|
--libexecdir=/usr/lib \
|
|
--localstatedir=/var \
|
|
--with-udev-rules-dir=/usr/lib/udev/rules.d \
|
|
--with-database=tdb \
|
|
--disable-tcpwrap \
|
|
--disable-rpath \
|
|
--disable-default-build-tests
|
|
|
|
# fight unused direct deps
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
|
|
make
|
|
}
|
|
|
|
package_pulseaudio() {
|
|
depends=("libpulse=$pkgver-$pkgrel" rtkit libltdl speex tdb systemd fftw orc
|
|
libsamplerate webrtc-audio-processing sbc)
|
|
optdepends=('avahi: zeroconf support'
|
|
'bluez: bluetooth support'
|
|
'jack: jack support'
|
|
'lirc-utils: infra-red support'
|
|
'openssl: RAOP support'
|
|
'pyqt4-python2: Equalizer GUI (qpaeq)')
|
|
backup=(etc/pulse/{daemon.conf,default.pa,system.pa})
|
|
install=pulseaudio.install
|
|
|
|
cd $pkgbase-$pkgver
|
|
make DESTDIR="$pkgdir" install \
|
|
bashcompletiondir=/usr/share/bash-completion/completions
|
|
|
|
install -Dm644 shell-completion/pulseaudio-zsh-completion.zsh \
|
|
"$pkgdir/usr/share/zsh/site-functions/_pulseaudio"
|
|
|
|
# Speed up pulseaudio shutdown
|
|
# Lower resample quality, saves CPU
|
|
sed -e '/exit-idle-time/iexit-idle-time=0' \
|
|
-e '/resample-method/iresample-method=speex-float-0' \
|
|
-i "$pkgdir/etc/pulse/daemon.conf"
|
|
|
|
# Disable cork-request module, can result in e.g. media players unpausing
|
|
# when there's a Skype call incoming
|
|
sed -e 's|/usr/bin/pactl load-module module-x11-cork-request|#&|' \
|
|
-i "$pkgdir/usr/bin/start-pulseaudio-x11"
|
|
|
|
# Make ConsoleKit optional
|
|
sed -e $'/load-module module-console-kit/{i.nofail\n;a.fail\n;}' \
|
|
-i "$pkgdir/etc/pulse/default.pa"
|
|
|
|
# Python fix
|
|
sed -i '1s:python$:&2:' "$pkgdir/usr/bin/qpaeq"
|
|
|
|
rm "${pkgdir}/etc/xdg/autostart/pulseaudio.desktop"
|
|
rm "${pkgdir}/etc/xdg/autostart/pulseaudio-kde.desktop"
|
|
|
|
# Delay of sound notification workaround, needs to be removed once fixed in systemd
|
|
sed -e 's/load-module module-udev-detect/load-module module-udev-detect tsched=0/' \
|
|
-i "${pkgdir}/etc/pulse/default.pa"
|
|
|
|
# Used only for SystemWide no needed for us
|
|
# http://www.freedesktop.org/wiki/Software/PulseAudio/Documentation/User/WhatIsWrongWithSystemWide/
|
|
rm "$pkgdir/etc/dbus-1/system.d/pulseaudio-system.conf"
|
|
|
|
# cap is handled in .install
|
|
chmod 755 "$pkgdir/usr/lib/pulse/proximity-helper"
|
|
|
|
### Split libpulse
|
|
|
|
mkdir -p "$srcdir"/libpulse/{etc/pulse,usr/{bin,lib/pulseaudio,share/man/man{1,5}}}
|
|
|
|
mv {"$pkgdir","$srcdir/libpulse"}/etc/pulse/client.conf
|
|
|
|
mv "$pkgdir"/usr/bin/pa{cat,ctl,dsp,mon,play,rec,record} \
|
|
"$srcdir/libpulse/usr/bin"
|
|
|
|
mv "$pkgdir"/usr/lib/libpulse{,-simple,-mainloop-glib}.so* \
|
|
"$srcdir/libpulse/usr/lib"
|
|
|
|
mv "$pkgdir"/usr/lib/pulseaudio/libpulsedsp.so \
|
|
"$pkgdir"/usr/lib/pulseaudio/libpulsecommon-*.so \
|
|
"$srcdir/libpulse/usr/lib/pulseaudio"
|
|
|
|
mv {"$pkgdir","$srcdir/libpulse"}/usr/lib/cmake
|
|
mv {"$pkgdir","$srcdir/libpulse"}/usr/lib/pkgconfig
|
|
|
|
mv {"$pkgdir","$srcdir/libpulse"}/usr/include
|
|
|
|
mv "$pkgdir"/usr/share/man/man1/pa{cat,ctl,dsp,play}.1 \
|
|
"$srcdir/libpulse/usr/share/man/man1"
|
|
|
|
mv {"$pkgdir","$srcdir/libpulse"}/usr/share/man/man5/pulse-client.conf.5
|
|
mv {"$pkgdir","$srcdir/libpulse"}/usr/share/vala
|
|
}
|
|
|
|
package_libpulse() {
|
|
pkgdesc="$pkgdesc (client library)"
|
|
depends=(dbus libasyncns libcap libxtst libsm libsndfile json-c)
|
|
optdepends=('alsa-plugins: ALSA support'
|
|
'avahi: zeroconf support')
|
|
backup=(etc/pulse/client.conf)
|
|
|
|
mv "$srcdir"/libpulse/* "$pkgdir"
|
|
}
|