desktop/cantata/PKGBUILD

pkgname=cantata
pkgver=2.2.0
pkgrel=1
pkgdesc='Qt5 client for the music player daemon (MPD)'
arch=('x86_64')
url='https://github.com/CDrummond/cantata'
license=('GPL')
depends=('qt5-svg' 'qt5-multimedia' 'libmtp' 'libcddb' 'libmusicbrainz5' 'mpg123' 'taglib-extras' 'cdparanoia' 'media-player-info' 'udisks2')
optdepends=('perl-uri: dynamic playlist'
            'mpd: playback'
            'ffmpeg: ReplayGain support')
makedepends=('cmake' 'qt5-tools' 'ffmpeg')
install=$pkgname.install
source=("https://github.com/CDrummond/cantata/releases/download/v$pkgver/$pkgname-$pkgver.tar.bz2")
sha1sums=('e4ebd1777700cb3406725d905073dd6ea1382b4d')

prepare() {
  mkdir -p build
}

build() {
  cd build

  PATH=/usr/lib/qt5/bin:$PATH
  cmake ../$pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DENABLE_HTTP_STREAM_PLAYBACK=ON \
    -DENABLE_KDE=OFF -DENABLE_QT5=ON \
    -DENABLE_LIBVLC=OFF \
    -DENABLE_UDISKS2=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}