desktop/haskell-zlib/PKGBUILD

# Apps Packages for Chakra, part of www.chakra-project.org
# Maintainer: H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Stephen McIntosh <stephenmac7[at]gmail[dot]com>
#               Thomas Dziedzic <gostrc@gmail.com>
#               Vesa Kaihlavirta <vesa@archlinux.org>
#               Arch Haskell Team <arch-haskell@haskell.org>

_hkgname=zlib
pkgname=haskell-zlib
pkgver=0.5.4.1
pkgrel=2
pkgdesc="Compression and decompression in the gzip and zlib formats"
url="http://hackage.haskell.org/package/zlib"
license=('custom:BSD3')
arch=('x86_64' 'i686')
makedepends=()
depends=('ghc=7.6.3-1' 'haskell-base>=3' 'haskell-base<5' 'haskell-bytestring>=0.9' 'haskell-bytestring<0.12')
options=('strip')
source=("http://hackage.haskell.org/packages/archive/zlib/0.5.4.1/zlib-0.5.4.1.tar.gz")
install="haskell-zlib.install"
sha512sums=('aa3522a5704978badcf634e1d99282144f01ddee4600bd146631a3ee8b98080914eb2887869a5fa404dc9d1e438a5df87cf7d44548c2f3e1ec13ba19004ef985')

build() {
    cd "${srcdir}/zlib-0.5.4.1"
    runhaskell Setup configure \
        -O \
        ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } \
        --enable-split-objs \
        --enable-shared \
        --prefix="/usr" \
        --docdir="/usr/share/doc/haskell-zlib" \
        --libsubdir='$compiler/site-local/$pkgid'
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd "${srcdir}/zlib-0.5.4.1"
    install -D -m744 register.sh \
        "${pkgdir}/usr/share/haskell/haskell-zlib/register.sh"
    install -m744 unregister.sh \
        "${pkgdir}/usr/share/haskell/haskell-zlib/unregister.sh"
    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"

    # Documentation
    ln -s "/usr/share/doc/haskell-zlib/html" \
        "${pkgdir}/usr/share/doc/ghc/html/libraries/zlib"

    # License
    install -D -m644 LICENSE \
        "${pkgdir}/usr/share/licenses/haskell-zlib/LICENSE"
    rm -f "${pkgdir}/usr/share/doc/haskell-zlib/LICENSE"

    runhaskell Setup copy --destdir="${pkgdir}"
}