desktop/qupzilla/PKGBUILD

# Maintainer: Anke Boersma <abveritas@chakra-project.org>

pkgname=qupzilla
pkgver=1.4.4
pkgrel=1
pkgdesc="A very fast open source browser based on WebKit core"
url="http://www.qupzilla.com"
arch=('x86_64')
license=('GPL3')
depends=('qtwebkit' 'qtwebkit-plugins')
optdepends=('bash-completion: bash completion support')
categories=('network') 
changelog=${pkgname}.changelog
install=${pkgname}.install
source=("https://github.com/QupZilla/qupzilla/archive/v${pkgver}.tar.gz"
        #https://github.com/QupZilla/QupZilla/tarball/master/QupZilla-qupzilla-${pkgver}.tar.gz"
        #"https://github.com/downloads/QupZilla/qupzilla/QupZilla-${pkgver}.tar.gz"
        'searchenginesmanager.diff'
        'speeddial.diff'
        'preferences.diff'
        'qupzilla.diff'
        'start-white.png'
        'qupzilla.changelog')
sha256sums=('a41d324d42922ff0046faefd1e191b197de30793ee3e07b644f2d01e44c83851'
            '9ade9f0dfe46f50367a7a1b70f54720585a3bf4b34cd0b0fddf0773d069a6b62'
            '30085c4be4a47205c94c7549b49c6c9392d4133a046251d9fda800ddccb791f1'
            'fb4fe056e2d370240178b038083d899d0a05bfe77d694bed524dbbb10b305aae'
            '2907c41677e6b34e9841161c48997c34591e8b99a7ceb4ebfa8aba88a0b2d3c0'
            '5bdac9f329c5d240e9aa58d7960f5f8b4c372e8908e2cf1080a02619a4695f09'
            '6f3b069561d2b5512f10618f6b986a2e075901112da4c33febb083bc7679a309')

prepare() {
  cd "${pkgname}-${pkgver}"
  
  patch -p0 -i "${srcdir}/searchenginesmanager.diff"
  patch -p1 -i "${srcdir}/speeddial.diff"
  patch -p0 -i "${srcdir}/preferences.diff"
  patch -p0 -i "${srcdir}/qupzilla.diff"
}
         
build() {
  cd "${pkgname}-${pkgver}"

  export USE_WEBGL="true"
  export KDE="true"
  
  qmake QupZilla.pro
  make
}

package() {
  cd "${pkgname}-${pkgver}"

  make INSTALL_ROOT="${pkgdir}" install
  
  install -m 644 -p "${srcdir}/start-white.png" "${pkgdir}/usr/share/icons/start-white.png"
  
  # zsh completion
  install -Dm644 linux/completion/zsh_completion.sh \
    "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
  
  # install changelog
  install -Dm644 CHANGELOG "${startdir}/qupzilla.changelog"
}