desktop/kdenetwork-kget/PKGBUILD

# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Manuel Tortosa <manutortosa@chakra-project.org>

# Include global configuration
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname="kdenetwork-kget"
arch=('x86_64')
pkgver=${_kdever}
pkgrel=1
pkgdesc="Download manager"
url="http://kde.org/applications/internet/kget/"
depends=("kde-workspace=4.11.5" 'qca' 'kwebkitpart>=0.9.6' 'libktorrent>=1.0.4' 'libmms')
groups=("kde" "kdenetwork" "kde-uninstall")
categories=('network')
conflicts=("kdenetwork-common" "kdenetwork-doc" "kdenetwork-kget")
provides=("kdenetwork-kget")
replaces=("kdenetwork-kget")
install=kdenetwork.install
license=('GPL' 'LGPL' 'FDL')
options=('docs' '!header' 'debug' 'log')
makedepends=('pkg-config' 'cmake' 'automoc4' 'docbook-xsl')
source=("$_mirror/kget-$_kdever.tar.xz")
sha256sums=(`grep kget-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

build() {
    cd ${srcdir}/kget-$pkgver
    cmake . \
        -DCMAKE_BUILD_TYPE=${_build_type} \
        -DCMAKE_INSTALL_PREFIX=${_installprefix} \
        -DCMAKE_SKIP_RPATH=ON \
        -DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed'
    make
}

package() {
    cd ${srcdir}/kget-$pkgver
    make DESTDIR=${pkgdir} install
}