desktop/kaccounts-integration/PKGBUILD

# Contributions from Arch: https://www.archlinux.org/packages/kde-unstable/x86_64/kaccounts-integration/
# Include global configuration

pkgname=kaccounts-integration
pkgver=18.12.0
pkgrel=1
pkgdesc="Small system to administer web accounts for the sites and services across the KDE desktop, including: Google, Facebook, Owncloud, IMAP, Jabber and others"
arch=('x86_64')
url="https://projects.kde.org/projects/kdereview/kaccounts-integration"
license=('GPL')
depends=('kcmutils' 'kio' 'signon-kwallet-extension' 'signon-plugin-oauth2' 'signon-ui' 'ki18n' 'libaccounts-glib')
makedepends=('extra-cmake-modules' 'kdoctools' 'python')
groups=('kde-telepathy')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('7924bf7a0805481445b914fcf9f8f819e64f7ee57bdab79a4a187db0e369d2f3'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
    cd build
    make DESTDIR=${pkgdir} install
}