desktop/kde-baseapps/PKGBUILD

# Include global configuration
source ../kdeapps.conf

pkgbase=kde-baseapps
pkgname=('kdebase-dolphin'
         'kdebase-kdepasswd'
         'kdebase-kdialog'
         'kdebase-keditbookmarks'
         'kdebase-kfind'
         'kdebase-konq-plugins'
         'kdebase-konqueror'
         'kdebase-lib'
         'kdebase-plasma')
pkgver=${_kdever}
pkgrel=1
arch=('x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kde-uninstall' 'kde-applications' 'kdebase')
makedepends=('kdelibs' 'cmake' 'automoc4' 'tidyhtml' 'docbook-xsl')
options=('docs' 'debug')
source=("$_mirror/${pkgbase}-$_kdever.tar.xz")
sha256sums=(`grep ${pkgbase}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake_kf5 ../${pkgbase}-${pkgver} \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_SKIP_RPATH=ON
  make
}

package_kdebase-dolphin() {
  pkgdesc='File Manager'
  depends=('kdebase-runtime' 'kdebase-lib' 'baloo4-widgets')
  optdepends=('kdegraphics-svgpart: thumbailers for SVG files'
              'kdegraphics-thumbnailers: thumbnailers for various graphics files'
              'kdemultimedia-ffmpegthumbs: thumbnailers for video files'
              'kdemultimedia-mplayerthumbs: thumbnailers for video files'
              'kdesdk-thumbnailers: thumbnailers for development files'
              'icoutils: thumbnailers for MS files'
              'ruby: servicemenu installation'
              'konsolepart4: open terminal in context menu')
  url="http://kde.org/applications/system/dolphin/"
  install=dolphin.install

  cd "$srcdir"/build/dolphin
  make DESTDIR="$pkgdir" install
}

package_kdebase-kdepasswd() {
  pkgdesc='Change Password'
  depends=('kdebase-runtime' 'kdebase-lib')

  cd "$srcdir"/build/kdepasswd
  make DESTDIR="$pkgdir" install
  cd "$srcdir"/build/doc/kdepasswd
  make DESTDIR="$pkgdir" install
}

package_kdebase-kdialog() {
  pkgdesc='A utility for displaying dialog boxes from shell scripts'
  depends=('kdebase-runtime')

  cd "$srcdir"/build/kdialog
  make DESTDIR="$pkgdir" install
}

package_kdebase-keditbookmarks() {
  pkgdesc='Bookmark Organizer and Editor'
  depends=('kdebase-runtime')

  cd "$srcdir"/build/keditbookmarks
  make DESTDIR="$pkgdir" install
}

package_kdebase-kfind() {
  pkgdesc='Find Files/Folders'
  depends=('kdebase-runtime' 'kdebase-lib')
  url="http://kde.org/applications/utilities/kfind/"
  install='kde-baseapps.install'

  cd "$srcdir"/build/kfind
  make DESTDIR="$pkgdir" install
  cd "$srcdir"/build/doc/kfind
  make DESTDIR="$pkgdir" install
}

package_kdebase-konq-plugins() {
  pkgdesc='Extra plugins for Konqueror'
  depends=('kdebase-konqueror' 'tidyhtml')
  replaces=('konq-plugins')
  install='kde-baseapps.install'

  cd "$srcdir"/build/konq-plugins
  make DESTDIR="$pkgdir" install
}

package_kdebase-konqueror() {
  pkgdesc='KDE File Manager & Web Browser'
  depends=('dolphinpart4' 'kdebase-keditbookmarks')
  optdepends=('kwebkitpart: to enable webkit engine')
  url="http://kde.org/applications/internet/konqueror/"
  install='konqueror.install'
  conflicts=('kdebase-nsplugins')
  replaces=('kdebase-nsplugins')

  for i in konqueror doc/konqueror nsplugins; do
    cd "$srcdir"/build/${i}
    make DESTDIR="$pkgdir" install
  done
}

package_kdebase-lib() {
  pkgdesc='KDE libraries for the basic desktop applications'
  groups=()
  depends=('kdelibs')
  replaces=('kde-baseapps')
  conflicts=('kde-baseapps')
  provides=('kde-baseapps')

  cd "$srcdir"/build/lib
  make DESTDIR="$pkgdir" install
}

package_kdebase-plasma() {
  pkgdesc='Display the contents of folders (User´s home folder as default)'
  depends=('kdebase-workspace' 'kdebase-lib')
  groups=()

  cd "$srcdir"/build/plasma
  make DESTDIR="$pkgdir" install
}