desktop/musescore/PKGBUILD

pkgname=musescore
_pkgname=MuseScore
pkgver=3.0
pkgrel=1
pkgdesc="A music score editor written in Qt"
arch=('x86_64')
url="https://musescore.org/en/"
license=('GPL')
depends=('alsa-lib' 'libpulse' 'libsndfile' 'libvorbis' 'portaudio' 'portmidi' 'qt5-base'
         'qt5-declarative' 'qt5-svg' 'qt5-tools' 'qt5-webengine' 'qt5-xmlpatterns' 'zlib')
makedepends=('cmake' 'doxygen' 'lame' 'qt5-script' 'texlive-core' 'ccache')
optdepends=('lame: MP3 export')
categories=('multimedia')
source=("$pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$_pkgname/archive/v$pkgver.tar.gz"
        'musescore.conf')
sha256sums=('678143411342bc7290364f7e7eeaba33ad9391b35cf3b6038861f0691a642d0e'
            '397b5431137d468a64b768670efdf385c27cb7298ee9295a32323a2610427928')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../$_pkgname-$pkgver \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DUSE_SYSTEM_FREETYPE=ON

  make lrelease
  make
}

package() {
  cd build
  make DESTDIR=$pkgdir install
}