desktop/clementine/PKGBUILD

# maintainer abveritas@chakra-project.org
# contributor Giuseppe Calà <jiveaxe@gmail.com>

pkgname=clementine
pkgver=1.1.1
pkgrel=6
pkgdesc="A modern music player and library organiser and a port of Amarok 1.4, with some features rewritten to take advantage of Qt4."
url="http://www.clementine-player.org/"
screenshot="http://images.clementine-player.org/screenshots/clementine-1.0-3.png"
license="GPL"
arch=('x86_64')
install="${pkgname}.install"
depends=('gstreamer0.10-base' 'taglib' 'glew' 'liblastfm' 'libgpod' 'libmtp' 'libplist'
         'hicolor-icon-theme' 'qtwebkit' 'libimobiledevice' 'qjson' 'glew' 'protobuf'
         'libcdio' 'qca' 'qca-ossl' 'chromaprint')
makedepends=('cmake' 'boost' 'mesa')
optdepends=('gstreamer0.10-base-plugins: for more open formats'
            'gstreamer0.10-good-plugins: for use with "Good" plugin libraries'
            'gstreamer0.10-bad-plugins: for use with "Bad" plugin libraries'
            'gstreamer0.10-ugly-plugins: for use with "Ugly" plugin libraries')
categories=('multimedia')
source=("http://clementine-player.googlecode.com/files/${pkgname}-${pkgver}.tar.gz"
        "clementine-1.1.1-libimobiledevice-fix.patch")
sha256sums=('a94dfbd4732155ff1d4f24bb792d9e4def5bf4a42dd6678638c0400217a6fda9'
            '688bdd15c898cb198dc85d58e2dedcca33771e374b4c6b621be723bafc167590')

prepare() {
  cd ${pkgname}-${pkgver}

  patch -Np1 -i ../clementine-1.1.1-libimobiledevice-fix.patch
}

build() {
  cd ${pkgname}-${pkgver}

  mkdir -p build && cd build
  cmake ../ -DCMAKE_INSTALL_PREFIX=/usr \
            -DCMAKE_BUILD_TYPE=Release \
            -DSTATIC_SQLITE=OFF
  make
}

package() {
  cd ${pkgname}-${pkgver}/build
  make install DESTDIR="${pkgdir}"
}