desktop/smplayer/PKGBUILD

pkgname=smplayer
pkgver=16.11.0
pkgrel=1
pkgdesc="A complete front-end for MPlayer"
arch=('x86_64')
url="http://smplayer.sourceforge.net/"
license=('GPL')
depends=('qt5-script' 'mplayer' 'hicolor-icon-theme' 'libxkbcommon-x11')
makedepends=('qt5-tools')
optdepends=('smplayer-themes: icon themes collection'
            'smplayer-skins: skin themes collection'
            'smtube: browse and play youtube videos'
            'mpv: for using mpv instead of mplayer')
categories=('multimedia')
install=smplayer.install
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
sha256sums=('e53a5d8b4d66fb0b7eb73053ef0bfdd2d942b79a16f8cc8d3d0b0771c7c80b5a')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make PREFIX=/usr QMAKE=qmake-qt5 LRELEASE=lrelease-qt5 \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="$pkgdir" PREFIX="/usr" install
    
  # Icon
  install -dm755 ${pkgdir}/usr/share/pixmaps
  ln -s /usr/share/icons/hicolor/64x64/apps/smplayer.png \
        ${pkgdir}/usr/share/pixmaps/

  # Menu entries.
  sed -i 's|Exec=smplayer %U|Exec=smplayer %F|' ${pkgdir}/usr/share/applications/smplayer.desktop || return 1
  sed -i 's|Exec=smplayer -add-to-playlist %U|Exec=smplayer -add-to-playlist %F|' \
  	${pkgdir}/usr/share/applications/smplayer_enqueue.desktop 
}