desktop/kde-dev-scripts/PKGBUILD

# Include global configuration

pkgname="kde-dev-scripts"
arch=('x86_64')
pkgver=18.08.1
pkgrel=1
pkgdesc='Scripts and setting files useful during development of KDE software'
url='https://www.kde.org/applications/development/'
arch=(any)
license=(GPL LGPL FDL)
groups=(kde-applications kdesdk)
makedepends=(extra-cmake-modules kdoctools kdelibs4support)
replaces=(kdesdk-scripts)
conflicts=(kdesdk-scripts kdesdk-doc)
options=('docs' 'debug')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('2549317ca43b85fbdbe642c82f4512ffc72aa8124b6ea4f86020de5a2c1726f8'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
  
    # Fix python 2 path
    sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
    "$pkgdir"/usr/bin/{zonetab2pot.py,kde-systemsettings-tree.py,reviewboard-am}
    sed -i 's|#! /usr/bin/env python|#!/usr/bin/env python2|' \
    "$pkgdir"/usr/bin/{kdelnk2desktop.py,kde_generate_export_header}

    # Install additional files
    cd "$srcdir"/$pkgname-$pkgver
    mkdir -p "$pkgdir"/usr/share/kde-dev-scripts
    cp -r kde-devel-* gdb "$pkgdir"/usr/share/kde-dev-scripts
}