desktop/kcron/PKGBUILD

# Include global configuration

pkgname="kcron"
arch=('x86_64')
pkgver=18.12.2
pkgrel=1
url="http://userbase.kde.org/KCron"
screenshot='https://userbase.kde.org/File:Kcron-screenshot-de.png'
license=('GPL' 'LGPL' 'FDL')
pkgdesc="Crontab editor"
depends=("kio")
makedepends=('extra-cmake-modules' 'kdoctools' 'python3')
groups=('kde' 'kde-uninstall' 'kde-applications' 'kdeadmin')
conflicts=("kdeadmin-kcron")
replaces=("kdeadmin-kcron")
provides=("kdeadmin-kcron")
options=('docs' 'debug')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('b5916d93135652e6812006473ebbcc694b18af2a8030c0ce0f0574a3f818d7f7'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}