desktop/openttd/PKGBUILD

#
# Games Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio) <adriyetichaves@gmail.com>

pkgname=openttd
pkgver=1.3.3
pkgrel=1
pkgdesc="An engine for running Transport Tycoon Deluxe or alternative data files"
arch=('i686' 'x86_64')
url='http://www.openttd.org'
license=('GPL2')
depends=('desktop-file-utils' 'fontconfig' 'hicolor-icon-theme' 'icu' 'libpng' 'sdl')
optdepends=('openttd-opengfx: graphic set.' 'openttd-openmsx: music set.' 'openttd-opensfx: sound set.')
conflicts=('openttd-dev' 'openttd-svn')
changelog=ChangeLog
categories=('games')
source=("http://binaries.openttd.org/releases/$pkgver/$pkgname-$pkgver-source.tar.xz")
md5sums=('97855877328d61d6c01833c8748a5b96')

build() {
  cd $srcdir/$pkgname-$pkgver 

 ./configure \
    --prefix-dir=/usr \
    --binary-name=$pkgname \
    --binary-dir=bin \
    --data-dir=share/$pkgname \
    --install-dir=$pkgdir \
    --doc-dir=share/doc/$pkgname \
    --menu-name="OpenTTD" \
    --personal-dir=.$pkgname    

  make
}

package() {
  cd $srcdir/$pkgname-$pkgver 
  make install
}