desktop/kamoso/PKGBUILD

pkgname=kamoso
pkgver=18.08.3
pkgrel=1
pkgdesc="Kamoso is an application to take pictures and videos out of your webcam."
url="https://userbase.kde.org/Kamoso"
arch=('x86_64')
license=('GPL')
depends=('qt5-gstreamer' 'purpose' 'gst-plugins-bad' 'qt5-quickcontrols')
makedepends=('extra-cmake-modules' 'kdoctools' 'boost' 'python3')
groups=(kde-applications kdemultimedia)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('14b230793c2e7b43914e5efab0f66adaa65007a2d2ffe6d155e0ef1cd38b006c'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@" 
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}