desktop/freeciv/PKGBUILD

pkgname=freeciv
pkgver=2.5.5
pkgrel=1
pkgdesc="Multiplayer clone of Civilization™."
arch=('x86_64')
url="http://www.freeciv.org/"
license=('GPL2')
depends=('bzip2' 'freetype2' 'readline' 'sqlite3' 'curl' 'libltdl' 'sdl' 'sdl_mixer' 'qt5-base')
makedepends=('qt5-tools')
changelog=ChangeLog
categories=('games')
backup=('etc/freeciv/database.lua')
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.bz2)
sha256sums=('5622f2142637057f7e47b1eda764c4e131222fab4d5bb42cd59fbd58ba3db1d4')

build() {
  cd $srcdir/$pkgname-$pkgver
  export MOCCMD="/usr/lib/qt5/bin/moc"
  export CXXFLAGS="$CXXFLAGS -std=c++11"
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --sysconfdir=/etc \
    --enable-client=qt \
    --enable-fcdb=sqlite3 \
    --enable-aimodules \
    --enable-shared
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver

  install -dm 755 $pkgdir/etc
  make DESTDIR=$pkgdir install

  # Link to Qt client.
  cd $pkgdir/usr/bin
  ln -s freeciv-qt freeciv
}