desktop/partitionmanager/PKGBUILD

# maintainer: Neophytos Kolokotronis <tetris4@gmail.com>

pkgname=partitionmanager
epoch=1
pkgver=1.1.0
pkgrel=2
pkgdesc="A KDE utility that allows you to manage disks, partitions, and file systems - Patched for Chakra Live ISO"
arch=('x86_64')
url="https://sourceforge.net/projects/partitionman"
license=('GPL2')
depends=('kde-runtime' 'parted' 'libatasmart')
makedepends=('cmake' 'automoc4' 'pkg-config' 'ntfs-3g')
optdepends=('e2fsprogs: ext2/3/4 support'
	    'xfsprogs: XFS support'
	    'jfsutils: JFS support'
	    'reiserfsprogs: Reiser support'
	    'ntfs-3g: NTFS support'
	    'dosfstools: FAT32 support'
            'btrfs-progs: btrfs support')
conflicts=('tribe-partitionmanager')
provides=('tribe-partitionmanager')
replaces=('tribe-partitionmanager<=1358163-8')
install=partitionmanager.install
options=(debug)
source=("http://download.kde.org/stable/${pkgname}/${pkgver}/src/${pkgname}-${pkgver}.tar.xz" tribe.patch) # disable-gpt.patch)
md5sums=('4a752c250fc5c98e22aba1d2ea309bec'
         'fae7de6edb04f8b17c31ed594a9a9b8e')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -Np1 -i ${srcdir}/tribe.patch
 } 

build() {
  cd ${pkgname}-${pkgver}

  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=RelWithDebInfo -DENABLE_UDISKS2=on

  make 
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}