desktop/kdeaccessibility/PKGBUILD

#
# KDE SC Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf



# original name (used for the source and pkgnames)
_origname=kdeaccessibility



#
# package info
#
pkgbase=('kdeaccessibility')
pkgname=('kdeaccessibility-common'
         'kdeaccessibility-doc'
         'kdeaccessibility-colorschemes'
         'kdeaccessibility-iconthemes'
         'kdeaccessibility-kmag'
         'kdeaccessibility-kmousetool'
         'kdeaccessibility-kmouth'
         'kdeaccessibility-kttsd')

# Disabled
#         'kdeaccessibility-ksayit'

arch=('i686' 'x86_64')
pkgver=${_kdever}
pkgrel=1

pkgdesc="split package"
url="http://www.kde.org"
license=('GPL' 'LGPL' 'FDL')

install=${_origname}.install
options=('docs')

makedepends=('pkgconfig' 'cmake' 'automoc4' "kdebase-runtime>=${_kdever}" "kdelibs>=${_kdever}" "speech-dispatcher>=0.6.7")

source=($_mirror/${_origname}-$_kdever.tar.bz2)
md5sums=('c8034d8475185faad52556ab61c55c56') # kdeaccessibility-4.4.5.tar.bz2



#
# build function
#
build()
{
	cd ${srcdir}/${_origname}-${pkgver}

	msg "starting build ..."
	cmake . -DCMAKE_BUILD_TYPE=${_build_type} \
		-DCMAKE_INSTALL_PREFIX=${_installprefix} \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed'

	make || return 1
}



#
# split-install functions
#
package_kdeaccessibility-common()
{
	pkgdesc="KDE Accessibility Aids - Common files"
	depends=("kdebase-runtime>=${_kdever}")
	conflicts=("kdemod-${_origname}-common")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	# include our patches into the package
	ls -1 ${startdir}/*.patch &>/dev/null 2>&1
	if [ "$?" = "0" ]; then
		warning "incuding patches into package"
		mkdir -p ${pkgdir}/usr/share/kdemod/patches/${_origname} &>/dev/null
		for i in ${startdir}/*.patch; do
			msg "$i"
			cp $i ${pkgdir}/usr/share/kdemod/patches/${_origname}/ &>/dev/null
		done
	else
		warning "no patches found, skipping to include them into the package..."
	fi
}

package_kdeaccessibility-doc()
{
	pkgdesc="KDE Accessibility Aids - Documentation"
	depends=("${_origname}-common>=${_kdever}")
	conflicts=("kdemod-${_origname}-doc")
	groups=("${_origname}" "kde-complete" "kde-uninstall" "kde-doc")

	splitdirs="doc"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-colorschemes()
{
	pkgdesc="Accessible Color Schemes for KDE"
	depends=("${_origname}-common>=${_kdever}")
	conflicts=("kdemod-${_origname}-colorschemes")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="ColorSchemes"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-iconthemes()
{
	pkgdesc="Accessibly Icon Themes for KDE"
	depends=("${_origname}-common>=${_kdever}")
	conflicts=("kdemod-${_origname}-iconthemes")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="IconThemes"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-kmag()
{
	pkgdesc="Screen magnifier"
	depends=("${_origname}-common>=${_kdever}" "kdebase-runtime>=${_kdever}" "kdelibs>=${_kdever}")
	conflicts=("kdemod-${_origname}-kmag")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="kmag"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-kmousetool()
{
	pkgdesc="Automatic mouse clicker"
	depends=("${_origname}-common>=${_kdever}" "kdebase-runtime>=${_kdever}" "kdelibs>=${_kdever}")
	conflicts=("kdemod-${_origname}-kmousetool")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="kmousetool"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-kmouth()
{
	pkgdesc="Speech synthesizer"
	depends=("${_origname}-common>=${_kdever}" "kdebase-runtime>=${_kdever}" "kdelibs>=${_kdever}")
	conflicts=("kdemod-${_origname}-kmouth")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="kmouth"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-kttsd()
{
	pkgdesc="Text-to-speech system"
	depends=("${_origname}-common>=${_kdever}" "kdebase-runtime>=${_kdever}" "kdelibs>=${_kdever}" "speech-dispatcher>=0.6.7")
	conflicts=("kdemod-${_origname}-kttsd")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="kttsd"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}

package_kdeaccessibility-ksayit()
{
	pkgdesc="Text-to-speech system frontend"
	depends=("${_origname}-common>=${_kdever}" "kdebase-runtime>=${_kdever}" "kdelibs>=${_kdever}" "kdeaccessibility-kttsd")
	conflicts=("kdemod-${_origname}-ksayit")
	groups=("kde-${_origname}" "kde-complete" "kde-uninstall")

	splitdirs="ksayit"
		for i in ${splitdirs} ; do
			cd ${srcdir}/${_origname}-${pkgver}/${i}
			make DESTDIR=${pkgdir} install
		done
}