desktop/soundkonverter/PKGBUILD

pkgname=soundkonverter
pkgver=3.0.1
pkgrel=1
pkgdesc="soundKonverter is a frontend to various audio converters"
arch=('x86_64')
url="https://github.com/HessiJames/soundkonverter"
license=('GPL')
depends=('hicolor-icon-theme' 'kdelibs4support' 'libkcddb' 'taglib')
makedepends=('cmake' 'extra-cmake-modules' 'kdesignerplugin' 'kdoctools')
optdepends=('cdrkit: cdda2wav backend'
            'faac: faac backend'
            'faad2: faad backend'
            'ffmpeg: ffmpeg backend'
            'flac: flac backend'
            'fluidsynth: flouidsynth backend'
            'lame: lame backend'
            'mac: mac backend'
            'mplayer: mplayer backend'
            'mp3gain: mp3gain backend'
            'opus-tools: opus backend'
            'speex: speexenc, speexdec backends'
            'timidity++: midi backend'
            'twolame: twolame backend'
            'vorbisgain: vorbisgain backend'
            'vorbis-tools: vorbis tools backend'
            'wavpack: wavpack backend'
            'sox: sox plugin (change sample rate, various effects)')
categories=('multimedia')
screenshot=('http://kde-apps.org/CONTENT/content-pre2/29024-2.png')
source=("$pkgname-$pkgver::https://github.com/HessiJames/soundkonverter/archive/v${pkgver}.tar.gz")
sha256sums=('92117f8aff85aac3a336cc0c94f3739aaa2d07ddd741d737dfd4b1571c60a0ce')

build() {
  mkdir -p "$srcdir/build"
  cd "$srcdir/build"

  cmake "$srcdir/$pkgname-$pkgver/src" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd "$srcdir/build"
  make DESTDIR="$pkgdir" install
}