desktop/libkgeomap/PKGBUILD

# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/libkgeomap
# Include global configuration
source ../kdeapps.conf

pkgname=libkgeomap
pkgver=${_kdever}
pkgrel=1
pkgdesc="A wrapper around world map components for browsing and arranging photos on a map"
url="https://projects.kde.org/projects/kde/kdegraphics/libs/libkgeomap"
arch=('x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('kdelibs' 'libmarble4')
makedepends=('cmake' 'automoc4')
install=${pkgname}.install
options=('docs' 'debug')
source=("$_mirror/${pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

prepare() {
  mkdir build

  # Fix build with libmarble4
  sed -e 's|#include <marble|#include <marble4|' -i $pkgname-$pkgver/libkgeomap/*.cpp -i $pkgname-$pkgver/libkgeomap/*.h
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}