desktop/ark/PKGBUILD

# Include global configuration

pkgname=ark
arch=('x86_64')
pkgver=18.07.90
pkgrel=1
pkgdesc="Archiver for various compression formats"
url="http://www.kde.org"
license=(GPL)
options=('docs' 'debug')
depends=(kpty khtml libarchive hicolor-icon-theme kitemmodels libzip)
makedepends=(extra-cmake-modules kdoctools python3)
optdepends=("p7zip: 7Z format support"
            "zip: ZIP format support"
            "unzip: ZIP format support"
            "unrar: RAR format support"
            "lrzip: Lzop, lzip and lrz format support")
conflicts=(kdeutils-ark)
replaces=(kdeutils-ark)
groups=('kde' 'kde-uninstall' 'kde-applications' 'kdeutils')

source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('d8798501df78475b461fd14977ac69bc8502c26e6ebe6351e450ad2d69659966'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}