desktop/ktp-contact-runner/PKGBUILD

# Contributions from Arch: https://www.archlinux.org/packages/extra/x86_64/telepathy-kde-contact-runner/
# Include global configuration

pkgname='ktp-contact-runner'
pkgver=18.07.90
pkgrel=1
arch=('x86_64')
url="https://community.kde.org/Real-Time_Communication_and_Collaboration"
license=('GPL')
pkgdesc='Finds entries from your KDE-Telepathy Contacts'
depends=('ktp-common-internals' 'krunner')
makedepends=('extra-cmake-modules' 'kdoctools' 'python3')
groups=('kde-telepathy')
source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('1eeefcfada0e9fbf9b3533e6d7cbf7d89a4a6bbdebc4e8d25f6106c2662a61c7'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
    cd build
    make DESTDIR=${pkgdir} install
}