desktop/kde-dev-utils/PKGBUILD

# Include global configuration

pkgname=kde-dev-utils
pkgver=18.04.3
pkgrel=1
arch=(x86_64)
pkgdesc="KDE Standard Development Toolkit Utilities"
url="http://www.kde.org"
license=('GPL' 'LGPL' 'FDL')
groups=("kde" "kdesdk" "kde-uninstall")
options=('docs' 'debug')
depends=(kparts qt5-tools)
makedepends=(extra-cmake-modules python3)
provides=('kmtrace' 'kpartloader' 'kprofilemethod' 'kstartperf' 'kuiviewer')
conflicts=('kdesdk-kmtrace' 'kdesdk-kpartloader' 'kdesdk-kprofilemethod' 'kdesdk-kstartperf' 'kdesdk-kuiviewer')
replaces=('kdesdk-kmtrace' 'kdesdk-kpartloader' 'kdesdk-kprofilemethod' 'kdesdk-kstartperf' 'kdesdk-kuiviewer')
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('73135c105880f31feb5f0ca3a3f603db5c357b00742d8ba9a5790b74713a449c'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR=${pkgdir} install
}