desktop/knightsgame/PKGBUILD

#
# Games Packages for Chakra, part of chakra-project.org
#
# Maintainer: Adrián Chaves Fernández (Gallaecio) <adriyetichaves gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Lauri Niskanen <ape@ape3000.com>

pkgname=knightsgame
_pkgname=knights
pkgver=022
pkgrel=2
pkgdesc='Action game that was originally released for Amiga in 1994.'
arch=('i686' 'x86_64')
url='http://www.knightsgame.org.uk/'
license=('GPL3')
depends=(boost-libs curl 'directfb' fontconfig sdl)
makedepends=(boost)
options=('!makeflags')
categories=('games')
source=("http://www.knightsgame.org.uk/files/${_pkgname}_${pkgver}_src.tar.gz" "boost.patch")
md5sums=('e840dacb0ccda4bd48768bd4e7068be0'
         'a74cf2b78a176385081d5d9d99024dee')

prepare() {
  cd ${_pkgname}_${pkgver}_src
  patch  -R -p2 < ${srcdir}/boost.patch # -R because I created the patch the wrong way around...
}

build() {
  cd ${_pkgname}_${pkgver}_src

  sed \
    -e 's/-mt//g' \
    -e "s/KNIGHTS_BINARY_NAME = knights/KNIGHTS_BINARY_NAME = $pkgname/" \
    -e "s/SERVER_BINARY_NAME = knights_server/SERVER_BINARY_NAME = $pkgname-server/" \
    -e "/^BOOST_LIBS/s|$| -lrt|" \
    -i Makefile \
    -i python/makemakefile.py
  make PREFIX=/usr
}

package() {
  cd ${_pkgname}_${pkgver}_src

  make PREFIX=$pkgdir/usr install
}