desktop/kdevelop-php/PKGBUILD

# maintainer: Neophytos Kolokotronis <tetris4@gmail.com>

pkgbase=kdevelop-php
pkgname=('kdevelop-php' 'kdevelop-php-docs')
pkgver=1.6.0
_pkgver=4.6.0
pkgrel=1
pkgdesc="PHP plugin for Kdevelop"
arch=('x86_64')
url="http://www.kdevelop.org/"
license=('GPL')
depends=("kdevelop=${_pkgver}" "kdevelop-pg-qt")
makedepends=('cmake' 'automoc4')
categories=('programming')
options=('!makeflags')
source=("http://download.kde.org/stable/kdevelop/${_pkgver}/src/${pkgname}-${pkgver}.tar.xz"
        "http://download.kde.org/stable/kdevelop/${_pkgver}/src/${pkgname}-docs-${pkgver}.tar.xz")
sha1sums=('705b1f36a6fbbac207e8ca78619827206b75b48e'
          '98d7efe6f983c4b439c6cbdc40d427e14954298f')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make

  cd "${srcdir}"
  mkdir build-docs
  cd build-docs
  # kdevelop-php-docs
  cmake ../${pkgname}-docs-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package_kdevelop-php() {
  optdepends=('kdevelop-php-docs: documentation')
  cd "${srcdir}/build"
  make DESTDIR="${pkgdir}" install
}

package_kdevelop-php-docs() {
  pkgdesc="Documentation for kdevelop-php"
  depends=("kdevelop-php=${pkgver}")
  cd "${srcdir}"/build-docs
  make DESTDIR="${pkgdir}" install
}