desktop/kdeedu-marble/PKGBUILD

# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: Manuel Tortosa <manutortosa@chakra-project.org>

# Include global configuration
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=kdeedu-marble
_pkgname=marble
pkgver=${_kdever}
pkgrel=1
pkgdesc="Desktop globe"
url="http://kde.org/applications/education/marble/"
screenshot="http://www.kde.org/images/screenshots/marble.png"
arch=('x86_64')
url='http://www.kde.org'
license=('GPL'
         'LGPL'
         'FDL')
depends=("kde-runtime>=${_kdever}"
         'shapelib')
makedepends=('cmake'
             'automoc4'
             'qt-mobility'
             'gpsd')
optdepends=('qt-mobility: enable QtMobility Location Provider'
            'gpsd: support for gps devices')
provides=('marble')
groups=("kde"
        "kdeedu"
        "kde-uninstall")
categories=('education')
options=('docs'
         '!header'
         'debug'
         'log')
install=${pkgname}.install
source=("$_mirror/${_pkgname}-$_kdever.tar.xz")
sha256sums=(`grep ${_pkgname}-$_kdever.tar.xz  ../checksums.txt | cut -d " " -f1`)

build() {
    cd ${srcdir}/${_pkgname}-${pkgver}
    cmake . \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=${_build_type} \
        -DCMAKE_SKIP_RPATH=ON \
        -DQTONLY=FALSE  \
        -DWITH_DESIGNER_PLUGIN=ON \
        -DCMAKE_{SHARED,MODULE,EXE}_LINKER_FLAGS='-Wl,--no-undefined -Wl,--as-needed'
    make
}

package() {
    cd ${srcdir}/${_pkgname}-${pkgver}
    make DESTDIR=${pkgdir} install
    
    # Cleanup unused files
    rm ${pkgdir}/usr/share/applications/kde4/marble-mobile.desktop
    rm ${pkgdir}/usr/share/applications/kde4/marble-qt.desktop
    rm ${pkgdir}/usr/share/applications/kde4/marble-touch.desktop

    rm ${pkgdir}/usr/bin/marble-mobile
    rm ${pkgdir}/usr/bin/marble-qt
    rm ${pkgdir}/usr/bin/marble-touch

}