add new dependency of audacity

portsmf/PKGBUILD

@@ -0,0 +1,41 @@
+# arch contributor: https://projects.archlinux.org/svntogit/packages.git/plain/trunk/PKGBUILD?h=packages/portsmf
+
+pkgname=portsmf
+pkgver=228
+pkgrel=1
+pkgdesc="Portable library for reading/writing Standard MIDI Files"
+arch=('i686' 'x86_64')
+url="http://sourceforge.net/p/portmedia/wiki/portsmf/"
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('subversion')
+options=('!staticlibs')
+source=(portsmf::svn+https://svn.code.sf.net/p/portmedia/code/portsmf/trunk#revision=$pkgver
+        portsmf-shared.patch)
+sha1sums=('SKIP'
+          'd07104f2b62e1458b8ff40b27673d992431d801d')
+
+pkgver() {
+  cd $pkgname
+  printf "%s" "$(svnversion | tr -d 'A-z')"
+}
+
+prepare() {
+  cd $pkgname
+  chmod 755 configure
+  patch -p1 -i "${srcdir}/portsmf-shared.patch"
+  autoreconf -f -i
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --libdir=/usr/lib --includedir=/usr/include/portsmf
+  make 
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="${pkgdir}" includedir=/usr/include/portsmf install
+  install -D -m644 portSMF.pc "${pkgdir}/usr/lib/pkgconfig/portSMF.pc"
+  install -D -m644 license.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}

portsmf/portsmf-shared.patch

@@ -0,0 +1,35 @@
+--- portsmf/configure.ac.orig	2013-06-22 20:54:59.000000000 +0200
++++ portsmf/configure.ac	2013-06-22 21:52:25.212040115 +0200
+@@ -23,7 +23,7 @@
+ dnl keep autools files in a subdirectory
+ AC_CONFIG_AUX_DIR(autotools)
+ # which also contains a subdir containing macros
+-AC_CONFIG_MACRO_DIR([autotools/m4])
++dnl AC_CONFIG_MACRO_DIR([autotools/m4])
+ dnl set up automake
+ AM_INIT_AUTOMAKE([-Wall foreign])
+ dnl Audacity policy: don't enable automatic rebuild of configure et al if 
+@@ -49,7 +49,7 @@
+ dnl we will need an "install" program to be available
+ AC_PROG_INSTALL
+ dnl and ranlib for static libraries
+-AC_PROG_RANLIB
++AC_PROG_LIBTOOL
+ 
+ dnl Make the install prefix available to the program so that the pkg-config file
+ dnl can be created correctly
+--- portsmf/Makefile.am.orig	2013-06-22 20:55:00.000000000 +0200
++++ portsmf/Makefile.am	2013-06-22 21:52:52.898705781 +0200
+@@ -6,10 +6,10 @@
+ ACLOCAL_AMFLAGS = -I autotools/m4
+ 
+ # define the output library (link with -lportSMF)
+-lib_LIBRARIES = libportSMF.a
++lib_LTLIBRARIES = libportSMF.la
+ 
+ # define the source files to use
+-libportSMF_a_SOURCES = allegro.cpp \
++libportSMF_la_SOURCES = allegro.cpp \
+ 	allegrosmfwr.cpp \
+ 	allegrord.cpp \
+ 	allegrowr.cpp \

sbsms/PKGBUILD

@@ -0,0 +1,24 @@
+# arch contributor: https://projects.archlinux.org/svntogit/packages.git/plain/trunk/PKGBUILD?h=packages/sbsms
+
+pkgname=sbsms
+pkgver=2.0.2
+pkgrel=1
+pkgdesc="Library for time stretching and pitch scaling of audio"
+arch=('i686' 'x86_64')
+url="http://sbsms.sourceforge.net/"
+license=('GPL')
+depends=('gcc-libs')
+options=('!staticlibs')
+source=(http://downloads.sourceforge.net/project/sbsms/$pkgname/$pkgver/lib$pkgname-$pkgver.tar.gz)
+sha1sums=('1842d0eae3cf5ac355d754e68fcdfd9391cd2fb7')
+
+build() {
+  cd lib$pkgname-$pkgver
+  ./configure --prefix=/usr --enable-shared
+  make
+}
+
+package() {
+  cd lib$pkgname-$pkgver
+  make DESTDIR="$pkgdir/" install
+}